############################
# Vincent Lefèvre's .zcomp #
############################

# Completion for zsh

zcomp_id='$Id: zcomp 73120 2014-09-16 11:39:50Z vinc17/ypig $'

# The following lines were added by compinstall

zstyle ':completion:*' auto-description 'specify: %d'
zstyle ':completion:*' completer _complete
zstyle ':completion:*' format 'Completing %d'
zstyle ':completion:*' ignore-parents parent pwd
zstyle ':completion:*' insert-tab false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' matcher-list '' 'm:{a-zA-Z}={A-Za-z}' 'r:|[._-]=* r:|=*'
zstyle ':completion:*' max-errors 1
zstyle ':completion:*' menu select=long
zstyle ':completion:*' preserve-prefix '//[^/]##/'
zstyle :compinstall filename '.zcomp'

autoload -U compinit
compinit
# End of lines added by compinstall

# Suggestion from
#   From: Peter Stephenson <pws@csr.com>
#   Date: Thu, 11 Mar 2004 12:28:17 +0000
#   Subject: Re: cd completion and CDABLE_VARS
#   To: zsh-users@sunsite.dk
#   Message-ID: <14646.1079008097@csr.com>
#   http://www.zsh.org/mla/users/2004/msg00150.html
# to disable named directories in the first completion choices.
zstyle ':completion:*:complete:(cd|pushd):*' tag-order \
  'local-directories path-directories directory-stack' '*'

# When starting to type a command, avoid the completion on directories
# and executables in the cwd (except if there are no matches). However
# if auto_cd is used with a cdpath, the behavior is a bit inconsistent.
# This can be fixed by a modified _autocd function.
zstyle ':completion:*:complete:-command-:*' tag-order 'commands builtins functions aliases suffix-aliases reserved-words jobs parameters' 'executables' '*'

# Suggestion from
#   From: Bart Schaefer <schaefer@brasslantern.com>
#   Date: Wed, 21 Jul 2004 17:32:36 -0700 (PDT)
#   Subject: Re: TAB at the command line beginning
#   To: Zsh Mailinglist <zsh-users@sunsite.dk>
#   Message-ID: <Pine.LNX.4.61.0407211649070.20062@toltec.zanshin.com>
#   http://www.zsh.org/mla/users/2004/msg00743.html
history-search-or-expand-or-complete()
{
  if [[ -z "$BUFFER" && -z "$PREBUFFER" ]] then
    zle history-incremental-search-backward "$@"
  else
    zle expand-or-complete "$@"
  fi
}
zle -N history-search-or-expand-or-complete
bindkey '\t' history-search-or-expand-or-complete

# Suggestion from
#   From: Bart Schaefer <schaefer@brasslantern.com>
#   Date: Thu, 19 Aug 2004 10:16:10 -0700 (PDT)
#   Subject: Re: Tip of the day: previous command output
#   To: Zsh-users List <zsh-users@sunsite.dk>
#   Message-ID: <Pine.LNX.4.61.0408190956440.9464@toltec.zanshin.com>
#   http://www.zsh.org/mla/users/2004/msg00896.html
# and following messages...
keep()
{
  kept=()
  kept=( $~* )
  if [[ ! -t 0 ]] then
    while read line; do
      kept+=( $line )
    done
  fi
  print -Rc - $kept
}
alias keep='noglob keep '

_insert_kept()
{
  (( $#kept )) || return 1
  local action
  zstyle -s :completion:$curcontext insert-kept action
  [[ -n $action ]] && compstate[insert]=$action
  compadd -a kept
}
zle -C insert-kept-result complete-word _generic
zstyle ':completion:insert-kept-result:*' completer _insert_kept
zstyle ':completion:*' insert-kept all
bindkey '\e\t' insert-kept-result

# Suggestion from the manual and
#   From: Bart Schaefer <schaefer@brasslantern.com>
#   Date: Sat, 19 Aug 2006 20:16:27 -0700
#   Subject: Re: How to insert completions on command line
#   To: zsh-users@sunsite.dk
#   Message-id: <060819201627.ZM28979@torch.brasslantern.com>
#   http://www.zsh.org/mla/users/2006/msg00820.html
zle -C all-matches complete-word _generic
bindkey '^X\t' all-matches
zstyle ':completion:all-matches:*' insert yes
zstyle ':completion:all-matches::::' completer _all_matches _complete

# See subthread
#   From: Peter Stephenson <pws@csr.com>
#   Date: Mon, 18 Jun 2007 11:09:48 +0100
#   Subject: Re: conditionally match part of file name to most recently
#           modified file
#   To: Zsh Users <zsh-users@sunsite.dk>
#   Message-ID: <20070618110948.3d8d739f@news01.csr.com>
#   http://www.zsh.org/mla/users/2007/msg00483.html
zle -C most-recent-file menu-complete _generic
bindkey '^X.' most-recent-file
zstyle ':completion:most-recent-file:*' match-original both
zstyle ':completion:most-recent-file:*' file-sort modification
zstyle ':completion:most-recent-file:*' file-patterns '*(-^/):all-files'
zstyle ':completion:most-recent-file:*' hidden all
zstyle ':completion:most-recent-file::::' completer _menu _files _match

# The pager-wrapper function, defined in .zalias, is regarded as a precommand.
compdef _precommand pager-wrapper

# Completion for user commands
compdef eclient=emacs
compdef svnwrapper=svn

# Note: interesting information can be obtained with _complete_help (^Xh).

# local variables:
# mode: sh
# end: