[PATCH] try to complete path in zfget

[PATCH] try to complete path in zfget

[Han Pingtian]

Hi,
Please review this patch. Thanks!

This patch will try to complete the path to a remote file recursively.

The only problem is that there are two categories listed:

% zfget dir/<tab>
remote directory
a  b  c
remote file
file1
---
 Functions/Zftp/zfget_match | 24 +++++++++++++++++++-----
 1 file changed, 19 insertions(+), 5 deletions(-)

diff --git a/Functions/Zftp/zfget_match b/Functions/Zftp/zfget_match
index 3a33c98..a440cac 100644
--- a/Functions/Zftp/zfget_match
+++ b/Functions/Zftp/zfget_match
@@ -9,17 +9,31 @@ if [[ $1 == $HOME || $1 == $HOME/* ]]; then
 fi
 
 if [[ $ZFTP_SYSTEM == UNIX* && $1 == */* ]]; then
-  setopt localoptions clobber
+  setopt localoptions clobber extendedglob
   local tmpf=${TMPPREFIX}zfgm$$
   zf_ln -fn =(<<<'') $tmpf || return 1
 
   if [[ -n $WIDGET ]]; then
-    local dir=${1:h}
+    local dir=${1%/*}
     [[ $dir = */ ]] || dir="$dir/"
     zftp ls -LF $dir >$tmpf
-    local reply
-    reply=(${${${(f)"$(<$tmpf)"}##$dir}%\*})
-    _wanted files expl 'remote file' compadd -P $dir - $reply
+    local reply1 reply2
+
+    # dirs in reply1, files in reply2
+    reply1=(${${(M)${${(f)"$(<$tmpf)"}##$dir}:#*/}%/})
+    reply2=(${${${${(f)"$(<$tmpf)"}##$dir}%\*}:#*/})
+
+    # try dir if ls -F doesn't work
+    if ! (($#reply1)); then
+      zftp dir $dir >$tmpf
+      reply1=(${(M)${(f)"$(<$tmpf)"}:#d([^[:space:]]##[[:space:]]##)(#c8)?##})
+      reply1=(${reply1/(#b)d([^[:space:]]##[[:space:]]##)(#c8)([^\/]##)\/#/$match[2]})
+
+      reply2=(${${(f)"$(<$tmpf)"}:#d([^[:space:]]##[[:space:]]##)(#c8)?##})
+      reply2=(${reply2/(#b)([^[:space:]]##[[:space:]]##)(#c8)(?##)/$match[2]})
+    fi
+    _wanted directories expl 'remote directory' compadd -S/ -q -P $dir - $reply1
+    _wanted files expl 'remote file' compadd -P $dir - $reply2
   else
     # On the first argument to ls, we usually get away with a glob.
     zftp ls "$1*$2" >$tmpf
-- 
1.9.3