zsh-workers
 help / color / mirror / code / Atom feed
* [PATCH] _debcheckout: New completion
@ 2015-08-28 23:34 Daniel Shahaf
  0 siblings, 0 replies; only message in thread
From: Daniel Shahaf @ 2015-08-28 23:34 UTC (permalink / raw)
  To: zsh-workers

>From Debian's 'devscripts' package.

---

#compdef debcheckout

# The helpstrings use the term 'checkout' (rather than 'clone' or 'branch' or
# 'fork') to be consistent with the name of the tool.

local -a args=(
'(-a --auth)'{-a,--auth}'[rewrite anonymous checkout URLs to authenticated ones]'
'(-p --print -d --details)'{-d,--details}'[print detailed information; do not checkout]'
'(-h --help)'{-h,--help}'[show usage message]'
'(-p --print -d --details)'{-p,--print}'[print summary information; do not checkout]'
'(-P --package)'{-P+,--package=}'[specify package name explicitly (when target is a URL)]:package name:_deb_packages available'
'(-t --type)'{-t+,--type=}'[specify repository type]:repository type:((arch\:Arch bzr\:Bazaar cvs\:CVS darcs\:Darcs git\:Git hg\:Mercurial svn\:Subversion))'
'(-u --username)'{-u+,--username=}'[specify username (implies --auth)]:username: '
\*{-f+,--file=}'[extract named file]:remote filename'
'--source=:policy for .orig.tar.gz file:(never auto download-only always)'
'--git-track=[specify branches to track]:branches (separated by spaces) or '\'\*\'
'1:package or URL: _alternative "_deb_packages available" "_urls"'
'2::destination directory:_path_files -/'
)

_arguments -s -S : "$args[@]"


^ permalink raw reply	[flat|nested] only message in thread

only message in thread, other threads:[~2015-08-28 23:34 UTC | newest]

Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2015-08-28 23:34 [PATCH] _debcheckout: New completion Daniel Shahaf

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).