* [PATCH] _debsnap: New completion function.
@ 2020-04-27 11:38 Daniel Shahaf
2020-04-27 19:35 ` Daniel Shahaf
0 siblings, 1 reply; 2+ messages in thread
From: Daniel Shahaf @ 2020-04-27 11:38 UTC (permalink / raw)
To: zsh-workers
---
Completion/Debian/Command/_debsnap | 52 ++++++++++++++++++++++++++++++
1 file changed, 52 insertions(+)
create mode 100644 Completion/Debian/Command/_debsnap
diff --git a/Completion/Debian/Command/_debsnap b/Completion/Debian/Command/_debsnap
new file mode 100644
index 000000000..40389375c
--- /dev/null
+++ b/Completion/Debian/Command/_debsnap
@@ -0,0 +1,52 @@
+#compdef debsnap
+
+# Based on debsnap from devscripts-2.20.3
+
+local context state state_descr line ret=1
+local -a expl
+typeset -A opt_args
+
+_arguments \
+ '(-d --destdir)'{-d+,--destdir=}'[set download directory]:download directory:_files -/' \
+ '(-f --force)'{-f,--force}'[allow non-empty destination directory]' \
+ '(-v --verbose)'{-v,--verbose}'[print configuration and report progress]' \
+ --list"[list versions; don't download]" \
+ --binary'[operate on binary packages (default: source packages)]' \
+ '*'{-a+,--architecture=}'[specify architectures to download]:architecture to download:_deb_architectures' \
+ --first='[download all versions newer than this]:version number (lower bound):->versions' \
+ --last='[download all versions older than this]:version number (upper bound):->versions' \
+ '(-)'{-h,--help}'[show usage information]' \
+ '(-)'--version'[show version number and license]' \
+ '1: :->package' \
+ '2:version number to download:->versions' \
+ && ret=0
+
+# -a implies --binary
+if (( ${+opt_args[-a]} || ${+opt_args[--architecture]} )); then
+ opt_args[--binary]=''
+fi
+
+case $state in
+ (package)
+ if (( ${+opt_args[--binary]} )); then
+ _description binary-packages expl 'binary package to download'
+ _deb_packages "${expl[@]}" avail && ret=0
+ else
+ _description source-packages expl 'source package to download'
+ _deb_packages "${expl[@]}" source && ret=0
+ fi
+ ;;
+ (versions)
+ local package=${(Q)line[1]}
+ if [[ -n $package ]]; then
+ local -a versions=( ${(f)"$(_call_program versions debsnap --list ${(@kv)opt_args[(I)(-a|--architecture|--binary)]} -- ${line[1]})"} )
+ # TODO: filter ${versions} to only those between ${opt_args[--first]} and ${opt_args[--last]}
+ _description versions expl ${state_descr}
+ compadd "$@" "${expl[@]}" -a versions && ret=0
+ else
+ _message -- $state_descr && ret=0
+ fi
+ ;;
+esac
+
+return ret
^ permalink raw reply [flat|nested] 2+ messages in thread
* Re: [PATCH] _debsnap: New completion function.
2020-04-27 11:38 [PATCH] _debsnap: New completion function Daniel Shahaf
@ 2020-04-27 19:35 ` Daniel Shahaf
0 siblings, 0 replies; 2+ messages in thread
From: Daniel Shahaf @ 2020-04-27 19:35 UTC (permalink / raw)
To: zsh-workers
Daniel Shahaf wrote on Mon, 27 Apr 2020 11:38 +0000:
> ---
> Completion/Debian/Command/_debsnap | 52 ++++++++++++++++++++++++++++++
> 1 file changed, 52 insertions(+)
> create mode 100644 Completion/Debian/Command/_debsnap
Revised version. The version numbers are now sorted «dpkg
--compare-versions»-ly rather than alphabetically, and are limited by
--first/--last. No other changes.
Cheers,
Daniel
[[[
#compdef debsnap
# Based on debsnap from devscripts-2.20.3
local context state state_descr line ret=1
local -a expl
typeset -A opt_args
_arguments \
'(-d --destdir)'{-d+,--destdir=}'[set download directory]:download directory:_files -/' \
'(-f --force)'{-f,--force}'[allow non-empty destination directory]' \
'(-v --verbose)'{-v,--verbose}'[print configuration and report progress]' \
--list"[list versions; don't download]" \
--binary'[operate on binary packages (default: source packages)]' \
'*'{-a+,--architecture=}'[specify architectures to download]:architecture to download:_deb_architectures' \
--first='[download all versions newer than this]:version number (lower bound):->versions' \
--last='[download all versions older than this]:version number (upper bound):->versions' \
'(-)'{-h,--help}'[show usage information]' \
'(-)'--version'[show version number and license]' \
'1: :->package' \
'2:version number to download:->versions' \
&& ret=0
# -a implies --binary
if (( ${+opt_args[-a]} || ${+opt_args[--architecture]} )); then
opt_args[--binary]=''
fi
case $state in
(package)
if (( ${+opt_args[--binary]} )); then
_description binary-packages expl 'binary package to download'
_deb_packages "${expl[@]}" avail && ret=0
else
_description source-packages expl 'source package to download'
_deb_packages "${expl[@]}" source && ret=0
fi
;;
(versions)
local package=${(Q)line[1]}
if [[ -n $package ]]; then
# Compute the arguments to --list
local -a args
() {
local i j
# repeatable flags with arguments, where the values can't contain colons
for i in ${(k)opt_args[(I)(-a|--architecture)]}; do
for j in ${(@s.:.)opt_args[$i]}; do
[[ -n $j ]] || continue
args+=( $i $j )
done
done
# non-repeatable flags with arguments, where the values may contain colons
for i in ${(k)opt_args[(I)(--first|--last)]}; do
# Avoid spurious "No matches" results in 'debsnap --first 42.1 --last 42.<TAB>'.
[[ $context != option${i}-* ]] || continue
# Un-escape colons (epoch separators in the version number)
args+=( $i ${(Q)opt_args[$i]} )
done
# flags without arguments
args+=( ${(k)opt_args[(I)(--binary)]} )
}
local -a versions=( ${(Oaf)"$(_call_program versions debsnap --list ${args} -- ${line[1]})"} )
_description -V versions expl ${state_descr}
compadd "$@" "${expl[@]}" -a versions && ret=0
else
_message -- $state_descr && ret=0
fi
;;
esac
return ret
]]]
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2020-04-27 19:36 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2020-04-27 11:38 [PATCH] _debsnap: New completion function Daniel Shahaf
2020-04-27 19:35 ` Daniel Shahaf
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).