zsh-workers
 help / color / mirror / code / Atom feed
* PATCH: lsns completion
@ 2021-10-20 18:48 Oliver Kiddle
  2021-10-21 14:27 ` Daniel Shahaf
  0 siblings, 1 reply; 2+ messages in thread
From: Oliver Kiddle @ 2021-10-20 18:48 UTC (permalink / raw)
  To: Zsh workers

This is a new completion for util-linux's lsns command.

We could call it to get namespaces to complete. But it is mostly useful
to specify them by pid with -p anyway and they are just big numbers.

Oliver

diff --git a/Completion/Linux/Command/_lsns b/Completion/Linux/Command/_lsns
new file mode 100644
index 000000000..994101d97
--- /dev/null
+++ b/Completion/Linux/Command/_lsns
@@ -0,0 +1,18 @@
+#compdef lsns
+
+local ign
+
+(( $#words > 2 )) && ign='!'
+_arguments -s -S \
+  '(-J --json)'{-J,--json}'[use JSON output format]' \
+  '(-l --list)'{-l,--list}'[use list format output]' \
+  '(-n --noheadings)'{-n,--noheadings}"[don't print headings]" \
+  '(-o --output)'{-o,--output}'[define which output columns to use]:column:_sequence compadd -M "m\:{a-z}={A-Z}" - NS TYPE PATH NPROCS PID PPID COMMAND UID USER NETNSID NSFS' \
+  '(-p --task)'{-p+,--task=}'[print process namespaces]:process id:_pids' \
+  '(-r --raw)'{-r,--raw}'[use the raw output format]' \
+  '(-u --notruncate)'{-u,--notruncate}"[don't truncate text in columns]" \
+  '(-W --nowrap)'{-W,--nowrap}"[don't use multi-line representation]" \
+  '(-t --type)'{-t+,--type=}'[filter by namespace type]:namespace type:(mnt net ipc user pid uts cgroup)' \
+  "$ign(- *)"{-h,--help}'[display usage information]' \
+  "$ign(- *)"{-V,--version}'[display version information]' \
+  '*: :_guard "^-*" namespace'


^ permalink raw reply	[flat|nested] 2+ messages in thread

* Re: PATCH: lsns completion
  2021-10-20 18:48 PATCH: lsns completion Oliver Kiddle
@ 2021-10-21 14:27 ` Daniel Shahaf
  0 siblings, 0 replies; 2+ messages in thread
From: Daniel Shahaf @ 2021-10-21 14:27 UTC (permalink / raw)
  To: zsh-workers

Oliver Kiddle wrote on Wed, Oct 20, 2021 at 20:48:53 +0200:
> This is a new completion for util-linux's lsns command.
> 
> We could call it to get namespaces to complete. But it is mostly useful
> to specify them by pid with -p anyway and they are just big numbers.

FWIW, "just big numbers" sounds to me like an argument in _favour_ of
completing them, to reduce typing errors in environments where
copy-paste isn't possible and so on.

Cheers,

Daniel


^ permalink raw reply	[flat|nested] 2+ messages in thread

end of thread, other threads:[~2021-10-21 14:27 UTC | newest]

Thread overview: 2+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2021-10-20 18:48 PATCH: lsns completion Oliver Kiddle
2021-10-21 14:27 ` Daniel Shahaf

Code repositories for project(s) associated with this inbox:

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).