From mboxrd@z Thu Jan  1 00:00:00 1970
Return-Path: <zsh-workers-return-37028-mason-zsh=primenet.com.au@zsh.org>
Received: (qmail 14794 invoked by alias); 31 Oct 2015 00:51:19 -0000
Mailing-List: contact zsh-workers-help@zsh.org; run by ezmlm
Precedence: bulk
X-No-Archive: yes
List-Id: Zsh Workers List <zsh-workers.zsh.org>
List-Post: <mailto:zsh-workers@zsh.org>
List-Help: <mailto:zsh-workers-help@zsh.org>
X-Seq: 37028
Received: (qmail 18589 invoked from network); 31 Oct 2015 00:51:17 -0000
X-Spam-Checker-Version: SpamAssassin 3.4.0 (2014-02-07) on f.primenet.com.au
X-Spam-Level: 
X-Spam-Status: No, score=-1.9 required=5.0 tests=BAYES_00,FREEMAIL_FROM,
	T_DKIM_INVALID autolearn=ham autolearn_force=no version=3.4.0
DKIM-Signature: v=1; a=rsa-sha256; c=relaxed/relaxed; d=yahoo.co.uk; s=s2048; t=1446252365; bh=XhxE0BD8xjRy1/iptwrsN/CPu2NyOej77Mtn2SA8RQM=; h=From:To:Subject:Date:From:Subject; b=OoWp8TT5j8hUkUvYc9bHZbiHkyd5B+tj+7ITGSSTCheSk/SyfNkxIKjJksQV/fC2MfH9Z9ILO8rcHH4b/kUoUuDjLBMSgSohr8O3ynGh9nKqrAkGqFaPowVkxSXUr1/+7irfbeXmfpcLuy3A9xwhZJYSKi4dSHAblzOxn/m1H7dP9HlTjvEOJ8GkbMfF5veYrN9xu9WQYN9mJq+MqbyB+y3mtYnTPmBgfhSCi10hQ3evGdLEn7N0Y3jKFw5hOupTDdVls2QnKgtta5EGTDZpQz7+RlniVWPx4irp7hgVdtKdhm4PfTi1RShJ9+FdrUCh3Uqf+cjuBMUKlP9dQdfvCA==
X-Yahoo-Newman-Id: 434498.75405.bm@smtp113.mail.ir2.yahoo.com
X-Yahoo-Newman-Property: ymail-3
X-YMail-OSG: zg1IMYwVM1mwcQrpE6Iq1FQD.C2AqBEPHSaj.Pr5S5xzGVC
 hwxusvyOJqd06RFV8oPFfiIkDlt.FtE9up1qeOaYr_Ba_KIDB.nkIrtKVTUV
 QTSA53LMdyrL1K1tKE8F94CN6Dqjvi76xl_Tza3XRlxN0Xt4QePT0_JFXJlw
 mR9SIHtQINsRv0eegovm6YtNAmkCKqOsiEly_yB.mhp_IxijI35YtXYelM0n
 L0_BlZzoB_rToNxCKaY0Bi2NWxykDgkKKv8ObRtTGTFuxaOOrKRrOscZHxFT
 ktdsYdwrfbL0wZiyS_2mSIF6B9GDv9.A1idNi3Mv9ftLjJDlKwzZjnbQFNty
 rN_YQQLjddTxhIKlNR_JMB7_Prwsk1ykaXAn4wHrvsnPdUTvvtZjdTWRICx9
 kPIJnA6ghb.QSeOfFrIrBeFxWosmrDkovH8dxKITTfFG95trZzLzVw6PF7oF
 xmu6GAWAv8ocJhH.Kj63JmF19Js8wYpoGu8_I53MsjzhwH.44Bch2x0x5Bv8
 EaqDcxJtWC0MuH11q65CDawKTRMqIHg--
X-Yahoo-SMTP: opAkk_CswBAce_kJ3nIPlH80cJI-
From: Oliver Kiddle <okiddle@yahoo.co.uk>
To: Zsh workers <zsh-workers@zsh.org>
Subject: PATCH: completion for software collections on Redhat
MIME-Version: 1.0
Content-Type: text/plain; charset="us-ascii"
Content-ID: <22711.1446252364.1@thecus.kiddle.eu>
Date: Sat, 31 Oct 2015 01:46:04 +0100
Message-ID: <22712.1446252364@thecus.kiddle.eu>

scl is a Redhat thing for using newer versions of stuff like gcc and
maven than the those the system comes with.

Oliver

diff --git a/Completion/Redhat/Command/_scl b/Completion/Redhat/Command/_scl
new file mode 100644
index 0000000..4b9c53b
--- /dev/null
+++ b/Completion/Redhat/Command/_scl
@@ -0,0 +1,38 @@
+#compdef scl
+
+local curcontext="$curcontext" dashes ret=1
+local -a state line force alts cmd
+
+[[ $words[2] = deregister ]] &&
+    force=( '--force[deregister even SCL installed as packages]' )
+
+_arguments -C $force \
+  '(- 1)'{-l,--list}'[list installed software collections or packages within a collection]' \
+  '(-l --list)1:action:(enable register deregister)' \
+  '(-)*:collections:->collections' && ret=0
+
+if [[ -n $state ]]; then
+  (( $#line > 1 )) && curcontext="${curcontext%:*}-$line[1]:"
+  if [[ $line[1] = register ]]; then
+    _directories -P / -W /
+    return
+  fi
+  if (( ${dashes:=$words[(I)--]} )); then
+    shift dashes words
+    (( CURRENT -= dashes ))
+    _normal
+    return
+  fi
+  if [[ $CURRENT -gt 3 && $words[CURRENT] = - ]]; then
+    compadd - --
+    return
+  fi
+  [[ $line[1] = enable && $CURRENT -gt 3 ]] &&
+    cmd='command:command:_cmdstring'
+
+  _alternative 'collections:collection:compadd
+      $(_call_program collections ${words[1]} -l)' \
+      $cmd && ret=0
+fi
+
+return ret