From: Oliver Kiddle <okiddle@yahoo.co.uk>
To: Zsh workers <zsh-workers@zsh.org>
Subject: PATCH: new column completion
Date: Thu, 05 Apr 2018 00:35:35 +0200 [thread overview]
Message-ID: <24373.1522881335@thecus> (raw)
Having been unchanged for years, the util-linux column command has
gained quite a bit of new functionality recently. This now adds
completion for it.
Oliver
diff --git a/Completion/Unix/Command/_column b/Completion/Unix/Command/_column
new file mode 100644
index 000000000..cb67fef37
--- /dev/null
+++ b/Completion/Unix/Command/_column
@@ -0,0 +1,59 @@
+#compdef column
+
+local ret=1
+local -a context state line expl args columns MATCH
+local -i MBEGIN MEND
+local -A opt_args
+
+case $OSTYPE in
+ linux-gnu)
+ args=(
+ '(info json -c --output-width)'{-c+,--output-width=}'[format output to fit display of specified width]:width'
+ + fill
+ '(info table text json -x --fillrows)'{-x,--fillrows}'[fill rows before filling columns]'
+ + table
+ '(info fill -t --table)'{-t,--table}'[create a table]'
+ '(info fill -s --separator)'{-s+,--separator=}'[specify column delimiters in input data]:delimiters'
+ '(info fill -O --table-order)'{-O+,--table-order=}'[specify order of output columns]: :->columns'
+ '(info fill -N --table-columns)'{-N+,--table-columns=}'[specify column names]:names'
+ '(info fill -H --table-hide)'{-H+,--table-hide=}"[don't print specified columns]: :->columns"
+ + text
+ '(info fill json -d --table-noheadings)'{-d,--table-noheadings}"[don't print header]"
+ '(info fill json -E --table-noextreme)'{-E,--table-noextreme}"[specify columns where length can be ignored]: :->columns"
+ '(info fill json -e --table-header-repeat)'{-e,--table-header-repeat}'[repeat header for each page]'
+ '(info fill json -R --table-right)'{-R+,--table-right=}'[right align text in these columns]: :->columns'
+ '(info fill json -T --table-truncate)'{-T+,--table-truncate=}'[truncate text in the columns when necessary]: :->columns'
+ '(info fill json -W --table-wrap)'{-W+,--table-wrap=}'[wrap text in the columns when necessary]: :->columns'
+ '(info fill json -r --tree)'{-r+,--tree=}'[specify column to format tree-like]: :->column'
+ '(info fill json -i --tree-id)'{-i+,--tree-id=}'[specify column containing ID for child-parent relations]: :->column'
+ '(info fill json -p --tree-parent)'{-p+,--tree-parent=}'[specify column containing reference to parent]: :->column'
+ + json
+ '(info fill text -n --table-name -c --output-width)'{-n+,--table-name=}'[specify table name for JSON output]:name'
+ '(info fill text -J --json -c --output-width)'{-J,--json}'[use JSON output format for table]'
+ + info
+ '(- *)'{-h,--help}'[display usage information]'
+ '(- *)'{-V,--version}'[display version information]'
+ )
+ ;;
+ *)
+ args=(
+ '(-t -s)-c+[format output to fit display of specified width]:width'
+ '(-c -x)-t[create a table]'
+ '(-c -x)-s+[specify column delimiters in input data]:delimiters'
+ '(-t -s)-x[fill rows before filling columns]'
+ )
+ ;;
+esac
+
+_arguments -s -S '*:file:_files' $args && ret=0
+
+if [[ -n $state ]]; then
+ columns=( ${(s.,.)${(Q)${opt_args[table--N]:-$opt_args[table---table-columns]}//(#m)\\([\\:])/${MATCH[2]}}} )
+ if (( $#columns )); then
+ ${${(M)state:#*s}:+_sequence} _wanted -C "$context[1]" columns expl column compadd -a - columns && ret=0
+ else
+ _message -e columns "$state"
+ fi
+fi
+
+return ret
reply other threads:[~2018-04-05 2:17 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=24373.1522881335@thecus \
--to=okiddle@yahoo.co.uk \
--cc=zsh-workers@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).