zsh-workers
 help / color / mirror / code / Atom feed
2b0c5580a5d4a359be2ad914420029c0677cef25 blob 3778 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
 
#compdef -redirect-,-default-,-default-

local -a match mbegin mend
local ret=1

# Look for glob qualifiers. This is duplicated from _path_files because
# we don't want to complete them multiple times (for each file pattern).
if _have_glob_qual $PREFIX; then
  compset -p ${#match[1]}
  compset -S '[^\)\|\~]#(|\))'
  if [[ $_comp_caller_options[extendedglob] == on ]] && compset -P '\#'; then
    _globflags && ret=0
  else
    if [[ $_comp_caller_options[extendedglob] == on ]]; then
      _describe -t globflags "glob flag" '(\#:introduce\ glob\ flag)' -Q -S '' && ret=0
    fi
    _globquals && ret=0
  fi
  return ret
fi

local opts tmp glob pat pats expl tag i def descr end ign tried
local type sdef ignvars ignvar prepath oprefix rfiles rfile

zparseopts -a opts \
    '/=tmp' 'f=tmp' 'g+:-=tmp' q n 1 2 P: S: r: R: W: X+: M+: F: J+: V+:

type="${(@j::M)${(@)tmp#-}#?}"
if (( $tmp[(I)-g*] )); then
  glob="${${${(@)${(@M)tmp:#-g*}#-g}##[[:blank:]]#}%%[[:blank:]]#}"
  [[ "$glob" = *[^\\][[:blank:]]* ]] &&
      glob="{${glob//(#b)([^\\])[[:blank:]]##/${match[1]},}}"

  # add `#q' to the beginning of any glob qualifier if not there already
  [[ "$glob" = (#b)(*\()([^\|\~]##\)) && $match[2] != \#q* ]] &&
      glob="${match[1]}#q${match[2]}"
elif [[ $type = */* ]]; then
  glob="*(#q-/)"
fi
tmp=$opts[(I)-F]
if (( tmp )); then
  ignvars=($=opts[tmp+1])
  if [[ $ignvars = _comp_ignore ]]; then
    ign=( $_comp_ignore )
  else
    ign=()
    for ignvar in $ignvars; do
      ign+=(${(P)ignvar})
    done
    opts[tmp+1]=_comp_ignore
  fi
else
  ign=()
fi

if zstyle -a ":completion:${curcontext}:" file-patterns tmp; then
  pats=()

  for i in ${tmp//\%p/${${glob:-\*}//:/\\:}}; do
    if [[ $i = *[^\\]:* ]]; then
      pats+=( " $i " )
    else
      pats+=( " ${i}:files " )
    fi
  done
elif zstyle -t ":completion:${curcontext}:" list-dirs-first; then
  pats=( " *(-/):directories:directory ${${glob:-*}//:/\\:}(#q^-/):globbed-files" '*:all-files' )
else
  # People prefer to have directories shown on first try as default.
  # Even if the calling function didn't use -/.
  pats=( "${${glob:-*}//:/\\:}:globbed-files *(-/):directories" '*:all-files ' )
fi

tried=()
for def in "$pats[@]"; do
  eval "def=( ${${def//\\:/\\\\\\:}//(#b)([][()|*?^#~<>])/\\${match[1]}} )"

  tmp="${(@M)def#*[^\\]:}"
  (( $tried[(I)${(q)tmp}] )) && continue
  tried=( "$tried[@]" "$tmp" )

  for sdef in "$def[@]"; do

    tag="${${sdef#*[^\\]:}%%:*}"
    pat="${${sdef%%:${tag}*}//\\:/:}"

    if [[ "$sdef" = *:${tag}:* ]]; then
      descr="${(Q)sdef#*:${tag}:}"
    else
      if (( $opts[(I)-X] )); then
        descr=
      else
        descr=file
      fi
      end=yes
    fi

    _tags "$tag"
    while _tags; do
      _comp_ignore=()
      while _next_label "$tag" expl "$descr"; do
        _comp_ignore=( $_comp_ignore $ign )
        if [[ -n "$end" ]]; then
          if _path_files -g "$pat" "$opts[@]" "$expl[@]"; then
	    ret=0
	  elif [[ $PREFIX$SUFFIX != */* ]] && zstyle -a ":completion:${curcontext}:$tag" recursive-files rfiles; then
	    local subtree
	    for rfile in $rfiles; do
	      if [[ $PWD/ = ${~rfile} ]]; then
		if [[ -z $subtree ]]; then
		  subtree=( **/*(/) )
		fi
		for prepath in $subtree; do
		  oprefix=$PREFIX
		  PREFIX=$prepath/$PREFIX
		  _path_files -g "$pat" "$opts[@]" "$expl[@]" && ret=0
		  PREFIX=$oprefix
		done
		break
	      fi
	    done
	  fi
        else
          _path_files "$expl[@]" -g "$pat" "$opts[@]" && ret=0
        fi
      done
      (( ret )) || break
    done

    ### For that _next_tags change mentioned above we would have to
    ### comment out the following line. (Or not, depending on the order
    ### of the patterns.)

    [[ "$pat" = '*' ]] && return ret

  done
  (( ret )) || return 0
done

return 1
debug log:

solving 2b0c5580a ...
found 2b0c5580a in https://git.vuxu.org/mirror/zsh/

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).