zsh-workers
 help / color / mirror / code / Atom feed
34bb6456088a693797b59ef8cb4c9c7c94ea43d2 blob 2091 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
 
#compdef links

local curcontext="$curcontext" state line ret=1
typeset -A opt_args

_arguments -C \
  '(-help)-anonymous[restrict links so that it can run on an anonymous account]' \
  '(-help)-assume-codepage[specify default codepage to use]:codepage' \
  '(-help)-async-dns[asynchronous DNS resolver]:bool:((0\:on 1\:off))' \
  '(-help)-download-dir[default download directory]:_files -/' \
  '(-help)-driver[graphics driver to use]:graphics driver:->graphics_drivers' \
  '(-help)-dump[dump the page as pure text]' \
  '(-help)-format-cache-size[number of formatted document pages cached]:pages' \
  '(-help)-ftp-proxy[specify ftp proxy server]:proxy:->proxies' \
  '(-help)-g[run in graphics mode rather than plain text mode]' \
  '-help[prints the help screen]' \
  '(-help)-http-proxy[specify web proxy server]:proxy:->proxies' \
  '(-help)-image-cache-size[image cache memory]:memory (kilobytes)' \
  '(-help)-max-connections[maximum number of concurrent connections]:connections' \
  '(-help)-max-connections-to-host[maximum number of concurrent connection to a given host]:connections' \
  '(-help)-memory-cache-size[cache memory]:kilobytes' \
  '(-help)-no-connect[runs links as a separate instance]' \
  '(-help)-receive-timeout[timeout on receive]:timeout (seconds)' \
  '(-help)-retries[number of retries]:retries' \
  '(-help)-source[dump the source page]' \
  '(-help)-unrestartable-receive-timeout[timeout on non restartable connections]:timeout (seconds)' \
  '(-help)-version[prints the links version number and exit]' \
  ':URL:->html' && ret=0

case $state in
  html)
    _alternative 'files:file:_files -g "*.x#html(-.)"' 'urls:URL:_urls' && ret=0
  ;;
  graphics_drivers)
    local -a vals
    vals=( ${=${${${(f)"$(_call_program links-graphics-drivers links -driver help 2>&1)"}[-1]}//','/''}} )
    _describe -t links-graphics-drivers 'graphics driver' vals && ret=0
  ;;
  proxies)
    local suf=-S:
    if compset -P '*:'; then
      _message -e ports 'port number'
    else
      compset -S ':*' && suf= 
      _hosts $suf && ret=0
    fi
  ;;  
esac

return ret
debug log:

solving 34bb64560 ...
found 34bb64560 in https://git.vuxu.org/mirror/zsh/

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).