zsh-workers
 help / color / mirror / code / Atom feed
3e2261a18fb373c934cc019ff8da0791c919be88 blob 729 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
#compdef entr

local curcontext="$curcontext" state state_descr line ret=1
typeset -A opt_args

_arguments -s -S \
  '(-r)-a[respond to all events rather than consolidating them to avoid looping]' \
  '-c[execute clear before invoking utility]' \
  '-d[track directories and exit if a new file is added]' \
  "-n[non-interactive mode; don't access TTY]" \
  '-p[postpone first execution of the utility]' \
  '(-a)-r[reload a persistent child process]' \
  '(*)-s[evaluate the first argument using interpreter specified by $SHELL]' \
  '(-): :->command' \
  '*::arguments:_normal' && ret=0

if [[ -n $state ]]; then
  if (( $+opt_args[-s] )); then
    _cmdstring && ret=0
  else
    _command_names -e && ret=0
  fi
fi

return ret
debug log:

solving 3e2261a18 ...
found 3e2261a18 in https://git.vuxu.org/mirror/zsh/

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).