438fcc858e990cae502a1a53028d02d95a47da41 blob 865 bytes (raw)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
| | #autoload
local i fds expl link sep
local -a list
fds=( /dev/fd/<0-9>(N:t) )
if zstyle -T ":completion:${curcontext}:" verbose && [[ -h /proc/$$/fd/$fds[1] ]]; then
zstyle -s ":completion:${curcontext}:" list-separator sep || sep=--
if zmodload -F zsh/stat b:zstat; then
for i in "${fds[@]}"; do
zstat +link -A link /proc/$$/fd/$i
list+=( "$i $sep ${link[1]}" )
done
elif (( $+commands[readlink] )); then
for i in "${fds[@]}"; do
list+=( "$i $sep $(readlink /proc/$$/fd/$i)" )
done
else
for i in "${fds[@]}"; do
list+=( "$i $sep $(ls -l /proc/$$/fd/$i|sed 's/.*-> //' )" )
done
fi 2>/dev/null
if (( $list[(I)* $sep ?*] )); then
_wanted file-descriptors expl 'file descriptor' compadd "$@" -d list -a - fds
return
fi
fi
_wanted file-descriptors expl 'file descriptor' compadd -a "$@" - fds
|
debug log:
solving 438fcc8 ...
found 438fcc8 in https://inbox.vuxu.org/zsh-workers/1434432668-18303-1-git-send-email-llua@gmx.com/
found 3e251b7 in https://git.vuxu.org/mirror/zsh/
preparing index
index prepared:
100644 3e251b73345490c9e14e9cd588f68c99300f4478 Completion/Zsh/Type/_file_descriptors
applying [1/1] https://inbox.vuxu.org/zsh-workers/1434432668-18303-1-git-send-email-llua@gmx.com/
diff --git a/Completion/Zsh/Type/_file_descriptors b/Completion/Zsh/Type/_file_descriptors
index 3e251b7..438fcc8 100644
Checking patch Completion/Zsh/Type/_file_descriptors...
Applied patch Completion/Zsh/Type/_file_descriptors cleanly.
index at:
100644 438fcc858e990cae502a1a53028d02d95a47da41 Completion/Zsh/Type/_file_descriptors
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).