zsh-workers
 help / color / mirror / Atom feed
444a1c80970fb63f7092f77802e6e4f874dc313d blob 2427 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
#compdef _arguments

# Dear reader: This function is called "__arguments" and is the completion
# function for the completion function _arguments.  This function, however, is
# not the completion function _arguments.  If you're looking for the function
# _arguments, then you've come to the wrong place.
#
# _arguments is a completion utility function.  It is called by completion
# functions for command-line tools.
#
# __arguments is a completion function for _arguments.  It runs when one does
# `_arguments -<TAB>' at the shell prompt to jog one's memory about _arguments'
# option flags.
#
# _arguments is in documented in the manual.  If you were looking for its
# source code, that'd be either in ../../../Completion/Base/Utility/_arguments
# or in ./_arguments, depending on where you're reading this file.
#
# __arguments takes no arguments, as ___arguments would tell you.

if (( ${words[(i)--]} < CURRENT )); then
  # "Deriving spec forms from the help output"
  _arguments : \
    '*-i[specify option name exclude patterns]:option name exclude pattern' \
    '*-s[specify option aliases]:pattern and replacement as "(this that)"' \
    '*:helpspec (pattern\:message\:action)'
else
  _arguments -A '-*' : \
    '-n[set $NORMARG]' \
    '-s[enable single-letter option stacking (-x -y == -xy)]' \
    '-w[(rarely needed) enable single-letter option stacking with arguments (-x X -y == -xy X)]' \
    '-W[(rarely needed) enable single-letter option stacking with arguments in the same word (-x X -y == -xXy)]' \
    "-C[modify \$curcontext for \`->action' (requires \`local curcontext')]" \
    "-R[when \`->action' matches, return 300]" \
    "-S[honour \`--' as end-of-options guard]" \
    "-A[do not complete options after non-options]:pattern matching unknown options (e.g., '-*')" \
    '-O[pass elements of array variable to function calls in actions]:array variable name:_parameters -g array' \
    "-M[specify matchspec for completing option names and values]:matchspec for completing option names and values (default\\: 'r\\:|[_-]=* r\\:|=*')" \
    '-0[have ${(v)opt_args} be NUL-joined rather than colon-escaped and colon-joined]' \
    "--[derive optspecs from \`\${command} --help' output]" \
    '1::optional delimiter:(\:)' \
    '*:spec (e.g., "*(-t --to)"{-t+,--to=}"[specify recipient]\:recipient'\''s address\:_email_addresses)'
  # TODO: doesn't support "Specifying Multiple Sets of Arguments"
fi
debug log:

solving 444a1c809 ...
found 444a1c809 in http://inbox.vuxu.org/zsh-workers/20210401000026.23570-2-danielsh@tarpaulin.shahaf.local2/
found 40a4e4b60 in http://inbox.vuxu.org/zsh-workers/20210401000026.23570-1-danielsh@tarpaulin.shahaf.local2/

applying [1/2] http://inbox.vuxu.org/zsh-workers/20210401000026.23570-1-danielsh@tarpaulin.shahaf.local2/
diff --git a/Completion/Zsh/Function/__arguments b/Completion/Zsh/Function/__arguments
new file mode 100644
index 000000000..40a4e4b60


applying [2/2] http://inbox.vuxu.org/zsh-workers/20210401000026.23570-2-danielsh@tarpaulin.shahaf.local2/
diff --git a/Completion/Zsh/Function/__arguments b/Completion/Zsh/Function/__arguments
index 40a4e4b60..444a1c809 100644

Checking patch Completion/Zsh/Function/__arguments...
Applied patch Completion/Zsh/Function/__arguments cleanly.
Checking patch Completion/Zsh/Function/__arguments...
Applied patch Completion/Zsh/Function/__arguments cleanly.

index at:
100644 444a1c80970fb63f7092f77802e6e4f874dc313d	Completion/Zsh/Function/__arguments

zsh-workers

This inbox may be cloned and mirrored by anyone:

	git clone --mirror http://inbox.vuxu.org/zsh-workers

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V1 zsh-workers zsh-workers/ http://inbox.vuxu.org/zsh-workers \
		zsh-workers@zsh.org
	public-inbox-index zsh-workers

Example config snippet for mirrors.
Newsgroup available over NNTP:
	nntp://inbox.vuxu.org/vuxu.archive.zsh.workers


code repositories for the project(s) associated with this inbox:

	https://git.vuxu.org/mirror/zsh/

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git