From: Marko Myllynen <myllynen@redhat.com>
To: zsh workers <zsh-workers@zsh.org>
Subject: [PATCH v2] zsh pidof completion
Date: Mon, 6 Jun 2016 11:42:21 +0300 [thread overview]
Message-ID: <5755376D.1070702@redhat.com> (raw)
Hi,
Below is zsh completions for the pidof(1) command tested with:
pidof from procps-ng 3.3.10
It would seem that pidof is Linux specific but if it's available for
other platforms then we could of course move it under Unix/Command (and
since ps(1) is horribly platform specific we'd need to handle different
ps(1) variants then).
This version now uses _sequence for -o as suggested by Daniel Shahaf.
It might also be nice to provide a generic _process_names type
completion like there's one now for _pids but I'll leave it for a
separate, future effort. _process_names would offer process names
instead of process IDs, there might few potential users for it in
the tree already (_killall, _lldb, and _pgrep).
---
Completion/Linux/Command/_pidof | 24 ++++++++++++++++++++++++
1 file changed, 24 insertions(+)
create mode 100644 Completion/Linux/Command/_pidof
diff --git a/Completion/Linux/Command/_pidof b/Completion/Linux/Command/_pidof
new file mode 100644
index 0000000..6361146
--- /dev/null
+++ b/Completion/Linux/Command/_pidof
@@ -0,0 +1,24 @@
+#compdef pidof
+
+local curcontext="$curcontext" state line expl ret=1
+typeset -A opt_args
+
+local exargs="-h --help -V --version"
+_arguments -C -s -w \
+ '(- *)'{-h,--help}'[display help information]' \
+ '(- *)'{-V,--version}'[print program version]' \
+ "(-s --single-shot $exargs)"{-s,--single-shot}'[return one PID only]' \
+ "(-c --check-root $exargs)"{-c,--check-root}'[omit processes with different root]' \
+ "(-x $exargs)"-x'[include shells running named scripts]' \
+ "($exargs)"\*{-o+,--omit-pid}'[omit processes with PIDs]:pids:_sequence -s , _pids' \
+ '*:process:->procnames' \
+ && return 0
+
+case $state in
+ procnames)
+ # Handle defunct processes and "avahi-daemon:"
+ _wanted values expl process compadd ${${${${${(@)${(f)"$(ps -N --ppid 2 -p 2 o args=)"}%% *}##*/}%:}#\[}%]} && ret=0
+ ;;
+esac
+
+return ret
Thanks,
--
Marko Myllynen
next reply other threads:[~2016-06-06 8:42 UTC|newest]
Thread overview: 2+ messages / expand[flat|nested] mbox.gz Atom feed top
2016-06-06 8:42 Marko Myllynen [this message]
2016-06-14 2:15 ` Eric Cook
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=5755376D.1070702@redhat.com \
--to=myllynen@redhat.com \
--cc=zsh-workers@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).