* completion file for the command 'cat'
@ 2013-10-27 16:06 Jun T.
0 siblings, 0 replies; only message in thread
From: Jun T. @ 2013-10-27 16:06 UTC (permalink / raw)
To: zsh-workers
[-- Attachment #1: Type: text/plain, Size: 124 bytes --]
Attached is a completion function for the command 'cat'.
Only Linux and Mac OS X (and relatives) are supported seriously.
[-- Attachment #2: _cat --]
[-- Type: application/octet-stream, Size: 1444 bytes --]
#compdef cat
local -a args
if _pick_variant gnu=GNU unix --version; then
args=(
'(-A --show-all)'{-A,--show-all}'[equivalent to -vET]'
'(-b --number-nonblank -n --number)'{-b,--number-nonblank}'[number nonempty output lines, overrides -n]'
'-e[equivalent to -vE]'
'(-E --show-ends)'{-E,--show-ends}'[display $ at end of each line]'
'(-n --number)'{-n,--number}'[number all output lines]'
'(-s --squeeze-blank)'{-s,--squeeze-blank}'[suppress repeated empty output lines]'
'-t[equivalent to -vT]'
'(-T --show-tabs)'{-T,--show-tabs}'[display TAB characters as ^I]'
'-u[ignored]'
'(-v --show-nonprinting)'{-v,--show-nonprinting}'[use ^ and M- notation, except for LFD and TAB]'
'(- : *)--help[display help and exit]'
'(- : *)--version[output version information and exit]'
'*:files:_files'
)
elif [[ "$OSTYPE" == (freebsd|dragonfly|darwin)* ]]; then
args=(
'(-n)-b[number non-blank output lines]'
'(-v)-e[display $ at the end of each line (implies -v)]'
'-n[number all output lines]'
'-s[squeeze multiple blank lines into one]'
'(-v)-t[display tab as ^I (implies -v)]'
'-u[do not buffer output]'
'-v[display non-printing chars as ^X or M-a]'
'(-)*:files:_files'
)
else
# POSIX reqires '-u', and most OSes may support '-n'
args=(
'-n[number all output lines]'
'-u[do not buffer output]'
'*:files:_files'
)
fi
_arguments -s -S : $args
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-10-27 16:07 UTC | newest]
Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2013-10-27 16:06 completion file for the command 'cat' Jun T.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).