7d6ed129f50c7b539737db9fc16150a521c202b4 blob 1284 bytes (raw)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
| | #compdef stg
typeset -a subcmds
subcmds=( ${${${(M)${(f)"$(stg help 2> /dev/null)"}## *}# }/#(#b)([^[:space:]]##)[[:space:]]##(*)/$match[1]:$match[2]} )
local curcontext="$curcontext" expl
local subcmd
local ret=1
if (( CURRENT == 2 )); then
_describe -t commands 'stgit command' subcmds && ret=0
else
shift words
(( CURRENT-- ))
subcmd="$words[1]"
curcontext="${curcontext%:*}-${subcmd}:"
case $subcmd in
(push)
_wanted -V unapplied-patches expl "patch" \
compadd ${${(M)${(f)"$(stg series 2> /dev/null)"}##- *}#- } \
&& ret=0
;;
(pop)
_wanted -V applied-patches expl "patch" \
compadd ${${(M)${(f)"$(stg series 2> /dev/null)"}##[+>] *}#[+>] } \
&& ret=0
;;
(edit|files|goto|rename|log|float|delete|sink|mail|sync|show|pick|hide)
_wanted -V patches expl "patch" \
compadd $(stg series --noprefix 2> /dev/null) \
&& ret=0
;;
(ref*)
last_word="$words[$CURRENT-1]"
refresh_patch_options=( -p --patch )
if [[ -n ${refresh_patch_options[(r)$last_word]} ]]; then
_wanted -V applied-patch expl "patch" \
compadd ${${(M)${(f)"$(stg series 2> /dev/null)"}##[+>] *}#[+>] } \
&& ret=0
else
_files && ret=0
fi
;;
(*)
_files && ret=0
;;
esac
fi
return ret
|
debug log:
solving 7d6ed129f ...
found 7d6ed129f in https://inbox.vuxu.org/zsh-workers/34487.1492098269@hydra.kiddle.eu/
found f313f651a in https://git.vuxu.org/mirror/zsh/
preparing index
index prepared:
100644 f313f651a2e322100a98c28eb005d2f010988602 Completion/Unix/Command/_stgit
applying [1/1] https://inbox.vuxu.org/zsh-workers/34487.1492098269@hydra.kiddle.eu/
diff --git a/Completion/Unix/Command/_stgit b/Completion/Unix/Command/_stgit
index f313f651a..7d6ed129f 100644
Checking patch Completion/Unix/Command/_stgit...
Applied patch Completion/Unix/Command/_stgit cleanly.
index at:
100644 7d6ed129f50c7b539737db9fc16150a521c202b4 Completion/Unix/Command/_stgit
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).