* Feature Request: completion for history events
@ 2022-12-29 12:39 Hendrik Jaeger
2023-01-17 2:34 ` Bart Schaefer
0 siblings, 1 reply; 3+ messages in thread
From: Hendrik Jaeger @ 2022-12-29 12:39 UTC (permalink / raw)
To: zsh-workers
[-- Attachment #1: Type: text/plain, Size: 947 bytes --]
Hi
I want to request a feature: completion for history events.
I imagine it to work like this:
typing this:
```
ls !<TAB>
```
should provide similar output to the 'first event' output when typing:
```
fc -<TAB>
```
I sometimes find myself in the situation that I need to reuse some argument from an earlier command (usually a filename) but I have no idea how many commands ago I used that argument.
Having tab-completion for '!' would allow me to see the history and pick the right command (e.g. -3) and following this up with the right argument index (e.g. :4) without having to cancel the command I already typed to look at the history.
I hope this description is clear but I’m happy to clarify any questions.
Also if there is another way of achieving the same goal, I might not be aware of it and would appreciate a pointer.
Thank you very much for considering this, but also for how awesome zsh already is!
henk
[-- Attachment #2: OpenPGP digital signature --]
[-- Type: application/pgp-signature, Size: 833 bytes --]
^ permalink raw reply [flat|nested] 3+ messages in thread
* Re: Feature Request: completion for history events
2022-12-29 12:39 Feature Request: completion for history events Hendrik Jaeger
@ 2023-01-17 2:34 ` Bart Schaefer
2023-01-17 2:36 ` Bart Schaefer
0 siblings, 1 reply; 3+ messages in thread
From: Bart Schaefer @ 2023-01-17 2:34 UTC (permalink / raw)
To: Hendrik Jaeger; +Cc: zsh-workers
On Thu, Dec 29, 2022 at 4:41 AM Hendrik Jaeger
<ml_zsh-workers@henk.geekmail.org> wrote:
>
> I want to request a feature: completion for history events.
The usual ways to do this aren't exactly what you're envisioning.
The first way is, instead of starting out by typing "!", simply type
ESC-/ (the default binding for the _history_complete_word widget).
Another way is to add _history to your completer zstyle so that
history words are included when you type TAB. Again you would not
start with "!", instead you'd type a few letters of the word you want,
or just hit TAB and find the word in the resulting list. E.g.:
zstyle ':completion:*' completer _oldlist _expand _complete _history
_approximate
Both of these are going to help you find the word you want and insert
the word directly, rather than completing a history event designator.
If you actually want to see a list of history events, we can build
something more complicated by stealing a bit of the guts of the _fc
completion function:
# --8< --
_complete_history_event () {
local -a events expl
local num cmd
if [[ $words[CURRENT] = '!'(|-) ]]
then
for num cmd in "${(kv@)history}"
do
(( num=num - HISTNO ))
events+=("${(r.1+$#HISTNO.)num} -- $cmd")
done
events=(${events/-/!-})
_wanted -2V events expl "history event" compadd -Q -ld events -
"${events[@]%% *}" &&
compstate[list]="list force"
else
return 1
fi
}
_mainly_complete_history() {
_main_complete _complete_history_event || _main_complete
}
zle -C complete-word .complete-word _mainly_complete_history
bindkey '\t' complete-word
# -->8 --
There's probably a better way to do that, the above is a quick hack
devised by looking at the _complete_debug output for "fc -".
^ permalink raw reply [flat|nested] 3+ messages in thread
* Re: Feature Request: completion for history events
2023-01-17 2:34 ` Bart Schaefer
@ 2023-01-17 2:36 ` Bart Schaefer
0 siblings, 0 replies; 3+ messages in thread
From: Bart Schaefer @ 2023-01-17 2:36 UTC (permalink / raw)
To: Hendrik Jaeger; +Cc: zsh-workers
On Mon, Jan 16, 2023 at 6:34 PM Bart Schaefer <schaefer@brasslantern.com> wrote:
>
> zstyle ':completion:*' completer _oldlist _expand _complete _history
> _approximate
>
> _wanted -2V events expl "history event" compadd -Q -ld events -
> "${events[@]%% *}" &&
Please excuse/undo gmail word-wrapping on those two lines.
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2023-01-17 2:36 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2022-12-29 12:39 Feature Request: completion for history events Hendrik Jaeger
2023-01-17 2:34 ` Bart Schaefer
2023-01-17 2:36 ` Bart Schaefer
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).