Re: [PATCH (not final)] (take three?) unset "array[$anything]"

[Bart Schaefer <schaefer@brasslantern.com>]

[-- Attachment #1: Type: text/plain, Size: 3153 bytes --]

On Thu, Jun 3, 2021 at 6:14 AM Stephane Chazelas <stephane@chazelas.org> wrote:
>
> If I understand correctly, the "stripquote" variant is the one
> where the user can do:
>
> unset 'hash["foo"]'
>
> unset "hash['']"
>
> unset "hash[${(qq)key}]"
>
> That is where quotes are parsed and removed but otherwise
> serve no purpose.

I guess you can describe it that way, yes.

> That hardly helps with backward compatibility as users who did
> work around the previous behaviour will still have to adapt
> their work around

The point of my previous analysis is that they probably will not have
to adapt.  Your $MATCH workaround operates correctly with the
stripquote version in nearly as many cases as it currently does (it is
not foolproof for the current shell implementation).

However, that doesn't mean I advocate for this over the "literal" variant.

> and those who didn't (who did unset
> "hash[$key]") will have their code choke on even more characters
> (", $, ' in addition to the previous ones, and likely more
> confusing behaviour when there are unmatched quotes or ()).

I extended my test set to include a number of variations on those
characters as well.  I've attached the test script.

Here are my test cases that fail if you just blindly do
  for k in ${(k)ax}; do unset "ax[$k]"; done
  typeset -p ax
with appropriate trapping for the fatal errors.  The literal variant
gets all of these, leaving the test hash empty.  Neither literal nor
stripquote throws any errors, so the trap is only needed for the
current implementation.  Starting with that:

typeset -A ax=(
  [$'\M-\C-@\\']=$'\M-\C-@\\'
  [$'\M-\C-@`']=$'\M-\C-@`'
  ['"${(@w)oops"']='"${(@w)oops"'
  ['(a']='(a'
  ['\$']='\$'
  ['\(']='\('
  ['\)']='\)'
  ['\[']='\['
  ['\\\']='\\\'
  ['\\\\']='\\\\'
  ['\]']='\]'
  ['\`']='\`'
)

The cases that fail with the stripquote variation:

typeset -A ax=(
  [$'\M-\C-@\\']=$'\M-\C-@\\'
  ['""']='""'
  ['"$oops"']='"$oops"'
  ['"safe"']='"safe"'
  ['"set"']='"set"'
  [\'\']=\'\'
  [\''safe'\']=\''safe'\'
  [\''set'\']=\''set'\'
  ['\!']='\!'
  ['\$']='\$'
  ['\(']='\('
  ['\)']='\)'
  ['\*']='\*'
  ['\=']='\='
  ['\@']='\@'
  ['\[']='\['
  ['\\\']='\\\'
  ['\\\\']='\\\\'
  ['\]']='\]'
  ['\`']='\`'
  ['\s\a\f\e']='\s\a\f\e'
  ['\s\e\t']='\s\e\t'
)

Current shell using $MATCH workaround:

typeset -A ax=(
  [$'\M-\C-@`']=$'\M-\C-@`'
  ['"${(@w)oops"']='"${(@w)oops"'
  ['(']='('
  ['(a']='(a'
  [')']=')'
  ['[']='['
  ['\(']='\('
  ['\)']='\)'
  ['\[']='\['
  ['\`']='\`'
  ['`']='`'
)

And stripquote with $MATCH workaround:

typeset -A ax=(
  ['""']='""'
  ['"$oops"']='"$oops"'
  ['"safe"']='"safe"'
  ['"set"']='"set"'
  [\'\']=\'\'
  [\''safe'\']=\''safe'\'
  [\''set'\']=\''set'\'
  ['\`']='\`'
)

Finally, literal with $MATCH workaround:

typeset -A ax=(
  [$'\M-\C-@\\']=$'\M-\C-@\\'
  ['\']='\'
  ['\!']='\!'
  ['\$']='\$'
  ['\(']='\('
  ['\)']='\)'
  ['\*']='\*'
  ['\=']='\='
  ['\@']='\@'
  ['\[']='\['
  ['\\\']='\\\'
  ['\`']='\`'
  ['\s\a\f\e']='\s\a\f\e'
  ['\s\e\t']='\s\e\t'
  [']']=']'
)

I agree that the literal variation is probably the one most useful to
re-apply in cases like read, print -v, etc.

[-- Attachment #2: test_unset.zsh --]
[-- Type: application/octet-stream, Size: 2033 bytes --]

exec 2>&1	# to see fatal error messages in proper sequence
unset ax bx oops
oops='this is a problem'
typeset -A ax bx
typeset -a kx=(
  '' '\' '`' '(' '[' ')' ']' '=' '"' "'" '!' '@' '$' '*'
  $'\0' '\\' '\`' '\(' '\[' '\)' '\]' '\=' '\!' '\@' '\$' '\*'
  '()safe' '(r)set' '(R)set' '(k)safe'	# look like valid subscript flags
  '(a' '(a)' '(n:foo:)a' '(n:1)a'	# look like invalid subscript flags
  'set' '"set"' \'set\' '\s\e\t'
  'safe' '"safe"' \'safe\' '\s\a\f\e'
  '\\' '\\\' '\\\\' '""' \'\'
  'two words' 'two  spaces' ' initial space' 'trailing space '
  $'\x80\\' $'\x80\`' $'\x80\~'		# broken UTF-8
  '?~>#'
  '$oops' '${oops}' '"$oops"' '"${(@w)oops"' '${(qqq)oops}' '$(echo oops)'
)
for ((i=0; i<255; i++)); do
  printf -v n '\\x%02x' $i
  eval "kx+=(\$'$n')"
done

for k in "$kx[@]"; do
  ax[$k]=$k
  bx[$k]=$k
done
typeset -p 1 ax
print COUNT: $#ax

print $'\nWith (b)'
for k in "$kx[@]"; do
  ( unset "ax[${(b)k}]" ) && unset "ax[${(b)k}]" &&
  print -r -- ${ax[$k]+Missed} ${(V)ax[$k]-Got $k}
done
typeset -p 1 ax

ax=(${(kv)bx})
print $'\nWith (q)'
for k in "$kx[@]"; do
  ( unset "ax[${(q)k}]" ) && unset "ax[${(q)k}]" &&
  print -r -- ${ax[$k]+Missed} ${(V)ax[$k]-Got $k}
done
typeset -p 1 ax

ax=(${(kv)bx})
print $'\nWith (qq)'
for k in "$kx[@]"; do
  ( unset "ax[${(qq)k}]" ) && unset "ax[${(qq)k}]" &&
  print -r -- ${ax[$k]+Missed} ${(V)ax[$k]-Got $k}
done
typeset -p 1 ax

ax=(${(kv)bx})
print $'\nWith (qqq)'
for k in "$kx[@]"; do
  ( unset "ax[${(qqq)k}]" ) && unset "ax[${(qqq)k}]" &&
  print -r -- ${ax[$k]+Missed} ${(V)ax[$k]-Got $k}
done
typeset -p 1 ax

ax=(${(kv)bx})
print $'\nWithout backslashes'
for k in "$kx[@]"; do
  ( unset "ax[$k]" ) && unset "ax[$k]" &&
  print -r -- ${ax[$k]+Missed} ${(V)ax[$k]-Got $k}
done
typeset -p 1 ax

ax=(${(kv)bx})
print $'\nWith pattern from workers/43269'
for k in "$kx[@]"; do
  ( unset "ax[${(*)k//(#m)[]\\]/\\$MATCH}]" ) &&
  unset "ax[${(*)k//(#m)[]\\]/\\$MATCH}]" &&
  print -r -- ${ax[$k]+Missed} ${(V)ax[$k]-Got $k}
done
typeset -p 1 ax
print COUNT: $#ax