From: Marlon Richert <marlon.richert@gmail.com>
To: Roman Perepelitsa <roman.perepelitsa@gmail.com>
Cc: Zsh hackers list <zsh-workers@zsh.org>
Subject: Re: [PATCH] Add customizable `vcs` prompt theme (was Re: [RFC][PATCH] `newuser` prompt theme)
Date: Wed, 9 Jun 2021 21:06:07 +0300 [thread overview]
Message-ID: <CAHLkEDuX-pSfSHXb6yE7HnrCfgZD9HB0U=hwi8huRxN0QeKbuA@mail.gmail.com> (raw)
In-Reply-To: <CAN=4vMqwAXM3AO1s91GEgDEWdOUS7mXA0SBceCZeCP_4dCoNfw@mail.gmail.com>
[-- Attachment #1: Type: text/plain, Size: 1282 bytes --]
On Wed, Jun 9, 2021 at 4:22 PM Roman Perepelitsa
<roman.perepelitsa@gmail.com> wrote:
>
> A few questions/comments after a cursory look.
>
> Why is prompt_vcs_chpwd using exec + read instead of $(...)?
Because I apparently forgot that $(...) runs in a subshell, too. ^_^;
> Why hook zle-line-init instead of precmd? There is a comment saying
> that it's "so you can press Enter on an empty line to update VCS info"
> but I don't understand it. When I press Enter in zle with an empty
> buffer, precmd does get called.
I could've sworn that precmd doesn't get called under those
conditions, but I guess I confused it with preexec.
> There is a race that may cause incorrect git status to be displayed.
> For example, suppose I run these commands in quick succession in a
> large git repository:
>
> git checkout -b foo
> git checkout -b bar
>
> If the two background vcs processes finish out of order, prompt will
> incorrectly display "foo" when the current branch is "bar". This error
> will persist until another command (perhaps empty) is executed.
>
> Pressing and holding Enter in a large repository may cause large (and
> unbounded) strain on the machine.
Thanks for the review! Here's a new version of the patch that
hopefully addresses the concerns you raised.
[-- Attachment #2: 0001-Add-customizable-vcs-prompt-theme.txt --]
[-- Type: text/plain, Size: 6449 bytes --]
From 41ffe718d7d58411254dc35f9618ae4fb0906aa6 Mon Sep 17 00:00:00 2001
From: Marlon Richert <marlon.richert@gmail.com>
Date: Wed, 9 Jun 2021 15:53:47 +0300
Subject: [PATCH] Add customizable `vcs` prompt theme
---
Functions/Prompts/prompt_vcs_setup | 180 +++++++++++++++++++++++++++++
1 file changed, 180 insertions(+)
create mode 100644 Functions/Prompts/prompt_vcs_setup
diff --git a/Functions/Prompts/prompt_vcs_setup b/Functions/Prompts/prompt_vcs_setup
new file mode 100644
index 000000000..8adc7c04d
--- /dev/null
+++ b/Functions/Prompts/prompt_vcs_setup
@@ -0,0 +1,180 @@
+##
+# Prompt that can be customized through vcs_info
+#
+
+autoload -Uz add-zsh-hook vcs_info
+
+# Prompt segments
+readonly -gHA _prompt_vcs_ps1=(
+ chpwd $'\n%B%F{blue}%~%%b%f/'
+ left $'%%(?,%F{green},%F{red})%#%%b%f%%s '
+ right '%B%F{blue}%n%b%f%k@%F{magenta}%m%f'
+ staged '%B%F{green}+%b%f'
+ unstaged '%B%F{red}*%b%f'
+ action '%B%F{red}%a%%b%f'
+ branch '%B%F{cyan}%b%%b%f'
+ repo '|%B%F{blue}%r%%b%f'
+)
+
+prompt_vcs_help() {
+ print -r -- \
+"This prompt theme can by customized by copy-pasting any of the code below to
+your .zshrc file and editing it there:
+
+ # For each of the following three entries:
+ # 1st string is printed after changing dirs.
+ # 2nd string is the left prompt.
+ # 3rd string is the right prompt and updated asynchronously.
+
+ # Normal prompt:
+ zstyle ':vcs_info:*:prompt_vcs:*' nvcsformats \\
+ "${(q+)_prompt_vcs_ps1[chpwd]//'%%'/%}" \\
+ "${(q+)_prompt_vcs_ps1[left]//'%%'/%}" \\
+ "${(q+)_prompt_vcs_ps1[right]//'%%'/%}"
+
+ # Prompt inside VCS repo:
+ zstyle ':vcs_info:*:prompt_vcs:*' formats \\
+ ${(q+)_prompt_vcs_ps1[chpwd]} \\
+ ${(q+)_prompt_vcs_ps1[left]} \\
+ ${(q+):-%u%c$_prompt_vcs_ps1[branch]$_prompt_vcs_ps1[repo]}
+
+ # Prompt during an ongoing VCS action:
+ zstyle ':vcs_info:*:prompt_vcs:*' actionformats \\
+ ${(q+)_prompt_vcs_ps1[chpwd]} \\
+ ${(q+)_prompt_vcs_ps1[left]} \\
+ ${(q+):-%u%c$_prompt_vcs_ps1[action]$_prompt_vcs_ps1[repo]}
+
+ # These set the values of %c and %u, respectively:
+ zstyle ':vcs_info:*:prompt_vcs:*' stagedstr ${(q+)_prompt_vcs_ps1[staged]}
+ zstyle ':vcs_info:*:prompt_vcs:*' unstagedstr ${(q+)_prompt_vcs_ps1[unstaged]}
+
+For more info on the settings above, see
+http://zsh.sourceforge.net/Doc/Release/Prompt-Expansion.html and the end of
+http://zsh.sourceforge.net/Doc/Release/User-Contributions.html#vcs_005finfo-Configuration"
+}
+
+# Sets a style if it hasn't been set yet.
+_prompt_vcs_zstyle() {
+ local -a val
+ zstyle -g val "$1" "$2"
+ (( $#val )) ||
+ zstyle "$@"
+}
+
+_prompt_vcs_info() {
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' max-exports 3 # Default is 2.
+
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' nvcsformats \
+ "${_prompt_vcs_ps1[chpwd]//'%%'/%}" \
+ "${_prompt_vcs_ps1[left]//'%%'/%}" \
+ "${_prompt_vcs_ps1[right]//'%%'/%}"
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' formats \
+ "$_prompt_vcs_ps1[chpwd]" \
+ "$_prompt_vcs_ps1[left]" \
+ "%u%c$_prompt_vcs_ps1[branch]$_prompt_vcs_ps1[repo]"
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' actionformats \
+ "$_prompt_vcs_ps1[chpwd]" \
+ "$_prompt_vcs_ps1[left]" \
+ "%u%c$_prompt_vcs_ps1[action]$_prompt_vcs_ps1[repo]"
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' stagedstr \
+ "$_prompt_vcs_ps1[staged]"
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' unstagedstr \
+ "$_prompt_vcs_ps1[unstaged]"
+
+ vcs_info prompt_vcs # Call with namespace.
+
+ print -rNC1 -- \
+ "${(q+)vcs_info_msg_0_}" "${(q+)vcs_info_msg_1_}" "${(q+)vcs_info_msg_2_}"
+}
+
+prompt_vcs_chpwd() {
+ emulate -L zsh
+
+ # Don't check for changes at this point, for performance reasons.
+ typeset -ga _prompt_vcs_info_msg_=( "${(0@Q)$(
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' check-for-changes no
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' check-for-staged-changes no
+ _prompt_vcs_info
+ )}" )
+ shift -p _prompt_vcs_info_msg_
+ print -Pr -- "$_prompt_vcs_info_msg_[1]"
+ PS1="$_prompt_vcs_info_msg_[2]"
+ RPS1="$_prompt_vcs_info_msg_[3]"
+}
+
+prompt_vcs_precmd() {
+ emulate -L zsh
+
+ # Kill any unfinished process before starting a new one.
+ if [[ -n $prompt_vcs_fd ]] && { : <&$prompt_vcs_fd } 2>/dev/null; then
+ zle -F "$prompt_vcs_fd" 2> /dev/null
+ exec {prompt_vcs_fd}<&-
+ fi
+
+ # Asynchronously check for changes.
+ typeset -gH prompt_vcs_fd=
+ exec {prompt_vcs_fd}< <(
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' check-for-changes yes
+ _prompt_vcs_zstyle ':vcs_info:*:prompt_vcs:*' check-for-staged-changes yes
+ _prompt_vcs_info
+ print -r -- "$PWD"
+ )
+
+ # Add callback. Needs to be a widget, so we can refresh the prompt.
+ zle -Fw "$prompt_vcs_fd" prompt_vcs_fd-widget
+}
+
+# Callback widget function for our async fetch of VCS changes
+prompt_vcs_fd-widget() {
+ emulate -L zsh
+
+ [[ -n $1 ]] ||
+ return # Don't accidentally close fd 0.
+ {
+ local -i fd=$1
+ zle -F "$fd" # Detach ourselves, so we don't get called more than once.
+
+ [[ -z $2 ]] ||
+ return # Error occured.
+
+ local -a reply
+ IFS=$'\0' read -Aru "$fd"
+ } always {
+ exec {fd}<&-
+ }
+ [[ $reply[-1] == $PWD ]] ||
+ return # Info is not for current dir.
+
+ shift -p reply
+ typeset -ga _prompt_vcs_info_msg_=( "${(@Q)reply}" )
+ RPS1="$_prompt_vcs_info_msg_[3]"
+ zle .reset-prompt
+}
+
+prompt_vcs_setup() {
+ prompt_opts=( cr percent sp ) # Tell promptinit which options to set.
+
+ # Indent left continuation prompt for each open shell construct.
+ local -a indent=( '%('{1..36}'_, ,)' )
+ PS2="${(j::)indent}"
+
+ RPS2='%F{yellow}# %^%f'
+ PS4=$'#->%(?,%F{green},%B%F{red}%S)%?%b%f%s\t%e+%F{green}%1N%f:%I %(1_,%F{yellow}%K{black}%_%f%k ,)'
+ SPROMPT='Correct %B%F{red}%U%R%b%f%u to %B%F{green}%r%b%f? [%Sy%ses|%Sn%so|%Se%sdit|%Sa%sbort] '
+ PROMPT_EOL_MARK='%S%F{cyan}%#%s%f'
+ zle_highlight=(
+ isearch:fg=black,bg=yellow
+ special:fg=cyan,bold
+ region:fg=white,bg=blue,bold
+ suffix:fg=white,bg=blue,bold
+ paste:bold
+ )
+
+ add-zsh-hook chpwd prompt_vcs_chpwd
+ add-zsh-hook precmd prompt_vcs_precmd
+ zle -N prompt_vcs_fd-widget # Callback widget for async VCS update.
+
+ prompt_vcs_chpwd
+}
+
+prompt_vcs_setup "$@"
--
2.30.1 (Apple Git-130)
next prev parent reply other threads:[~2021-06-09 18:07 UTC|newest]
Thread overview: 65+ messages / expand[flat|nested] mbox.gz Atom feed top
2021-04-13 19:41 [RFC][PATCH] `newuser` prompt theme Marlon
2021-04-13 20:31 ` Roman Perepelitsa
2021-04-13 20:44 ` Bart Schaefer
2021-04-14 5:09 ` Marlon Richert
2021-04-14 5:17 ` Bart Schaefer
2021-04-14 5:45 ` Marlon
2021-04-14 12:05 ` Daniel Shahaf
2021-04-14 13:17 ` Marlon
2021-04-14 14:09 ` Daniel Shahaf
2021-04-15 1:07 ` Bart Schaefer
2021-04-15 3:50 ` Marlon Richert
2021-04-15 20:27 ` Daniel Shahaf
2021-04-15 23:42 ` Daniel Shahaf
2021-04-15 11:11 ` Mikael Magnusson
2021-04-15 16:44 ` vcs_info's global variables (was: Re: [RFC][PATCH] `newuser` prompt theme) Daniel Shahaf
2021-04-16 16:04 ` [RFC][PATCH] `newuser` prompt theme Marlon
2021-04-16 17:13 ` Daniel Shahaf
2021-04-16 19:19 ` Marlon Richert
2021-04-16 19:30 ` Daniel Shahaf
2021-04-19 16:46 ` Marlon Richert
2021-05-02 17:18 ` Lawrence Velázquez
2021-05-03 2:38 ` Bart Schaefer
2021-05-03 4:11 ` Lawrence Velázquez
2021-05-03 11:38 ` [PATCH] Add customizable `vcs` prompt theme (was Re: [RFC][PATCH] `newuser` prompt theme) Marlon Richert
2021-05-09 18:04 ` Lawrence Velázquez
2021-05-31 1:01 ` Lawrence Velázquez
2021-06-09 12:58 ` Marlon Richert
2021-06-09 13:22 ` Roman Perepelitsa
2021-06-09 18:06 ` Marlon Richert [this message]
2021-06-10 9:30 ` Roman Perepelitsa
2021-06-10 13:47 ` Marlon Richert
2021-06-10 14:01 ` Marlon Richert
2021-06-10 17:45 ` Roman Perepelitsa
2021-06-20 22:13 ` Marlon Richert
2021-06-23 17:26 ` Roman Perepelitsa
2022-08-08 10:12 ` Marlon Richert
2022-08-08 10:17 ` Roman Perepelitsa
2021-04-14 14:09 ` sysexits.h codes? (was: " Daniel Shahaf
2021-04-30 19:40 ` Marlon Richert
2021-04-30 21:16 ` Daniel Shahaf
2021-04-30 21:34 ` Bart Schaefer
2021-05-01 15:09 ` Daniel Shahaf
2021-04-30 21:40 ` Bart Schaefer
2021-05-01 13:39 ` Marlon Richert
2021-05-01 14:43 ` Daniel Shahaf
2021-05-03 11:36 ` Marlon Richert
2021-05-03 16:04 ` Daniel Shahaf
2021-05-04 11:13 ` Marlon Richert
2021-05-21 11:38 ` Marlon Richert
2021-04-14 15:30 ` [RFC][PATCH] `newuser` prompt theme Arseny Maslennikov
2021-04-14 18:52 ` Daniel Shahaf
2021-04-14 14:00 ` precmd hooks and $? Bart Schaefer
2021-04-14 15:18 ` docs patches for precmd hooks and $?, and vcs_info Daniel Shahaf
2021-04-15 2:35 ` Bart Schaefer
2021-04-15 16:17 ` Archives render attachments as first-class messages (was: docs patches for precmd hooks and $?, and vcs_info) Daniel Shahaf
2021-04-15 18:54 ` [RFC][PATCH] Reset ZLE hooks when changing prompt themes (was Re: [RFC][PATCH] `newuser` prompt theme) Marlon
2021-04-15 21:34 ` Daniel Shahaf
2021-04-16 22:34 ` Marlon Richert
2021-04-25 16:08 ` Lawrence Velázquez
2021-05-02 17:03 ` Lawrence Velázquez
2021-05-02 17:59 ` Bart Schaefer
2021-05-05 6:10 ` Marlon Richert
2021-05-16 15:27 ` Lawrence Velázquez
2021-05-16 19:31 ` Marlon Richert
2021-05-17 4:19 ` Bart Schaefer
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to='CAHLkEDuX-pSfSHXb6yE7HnrCfgZD9HB0U=hwi8huRxN0QeKbuA@mail.gmail.com' \
--to=marlon.richert@gmail.com \
--cc=roman.perepelitsa@gmail.com \
--cc=zsh-workers@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).