zsh-workers
 help / color / mirror / code / Atom feed
b20c05c9c84c14f37723660f34843d999dc4cac3 blob 723 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
## vim:ft=zsh
## Written by Frank Terbeck <ft@bewatermyfriend.org>
## Distributed under the same BSD-ish license as zsh itself.

setopt localoptions NO_shwordsplit
local dirname=$1
local basedir="." file

basedir=${basedir:P}
while [[ ${basedir} != '/' ]]; do
    [[ -r ${basedir} ]] || return 1
    if [[ -n ${vcs_comm[detect_need_file]} ]] ; then
        [[ -d ${basedir}/${dirname} ]] && {
            for file in ${(s: :)${vcs_comm[detect_need_file]}}; do
                [[ -e ${basedir}/${dirname}/${file} ]] && break 2
            done
        }
    else
        [[ -d ${basedir}/${dirname} ]] && break
    fi

    basedir=${basedir:h}
done

[[ ${basedir} == "/" ]] && return 1
vcs_comm[basedir]=${basedir}
return 0
debug log:

solving b20c05c9c ...
found b20c05c9c in https://git.vuxu.org/mirror/zsh/

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).