c4d5abac162d78b958cd1f010ca7a1255b2d61b4 blob 1008 bytes (raw)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
| | #compdef unalias
_aliases_add() {
if zstyle -t ":completion:${curcontext}:$2" extra-verbose; then
local -a items=()
printf -v items "%s\:%s" "${(@q)${(@kvq)${(PAA)1}}}"
args+=( "${2}:${3}:(( ${items:#'\:'} ))" )
else
args+=( "${2}:${3}:compadd -k $1" )
fi
}
_aliases() {
local -a args=() sel=( -s rgs )
zparseopts -D -E -K s:=sel
shift sel
case $sel in
( *r* ) _aliases_add aliases aliases 'regular alias' ;|
( *g* ) _aliases_add galiases global-aliases 'global alias' ;|
( *s* ) _aliases_add saliases suffix-aliases 'suffix alias' ;|
( *R* ) _aliases_add dis_aliases disabled-aliases 'disabled regular alias' ;|
( *G* ) _aliases_add dis_galiases disabled-global-aliases 'disabled global alias' ;|
( *S* ) _aliases_add dis_saliases disabled-suffix-aliases 'disabled suffix alias' ;|
esac
local -a opts=( "$@" )
_alternative -O opts "$args[@]"
}
_aliases "$@"
|
debug log:
solving c4d5abac1 ...
found c4d5abac1 in https://inbox.vuxu.org/zsh-workers/CAHLkEDtg50kBkKoEfoW-wQ42bcrfZNLEWjDPDqnHunhmk0NRkw@mail.gmail.com/
found 6506ece13 in https://git.vuxu.org/mirror/zsh/
preparing index
index prepared:
100644 6506ece1376f08443eead3537f16eebcfb489259 Completion/Zsh/Type/_aliases
applying [1/1] https://inbox.vuxu.org/zsh-workers/CAHLkEDtg50kBkKoEfoW-wQ42bcrfZNLEWjDPDqnHunhmk0NRkw@mail.gmail.com/
diff --git a/Completion/Zsh/Type/_aliases b/Completion/Zsh/Type/_aliases
index 6506ece13..c4d5abac1 100644
Checking patch Completion/Zsh/Type/_aliases...
Applied patch Completion/Zsh/Type/_aliases cleanly.
index at:
100644 c4d5abac162d78b958cd1f010ca7a1255b2d61b4 Completion/Zsh/Type/_aliases
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).