zsh-workers
 help / color / mirror / code / Atom feed
d0ff085bb0732b3920822c7ab9ad1f085f72bbdc blob 810 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
 
#compdef timeout gtimeout

local args

if [[ $service = g* || $OSTYPE != *bsd* ]]; then
  # GNU coreutils as opposed to Free/NetBSD implementation
  args=(
    '(-v --verbose)'{-v,--verbose}'[indicate when signal is sent upon timeout]'
    '(- *)--help[display usage information]'
    '(- *)--version[display version information]'
  )
fi

_arguments -S -A "-" $args \
  '--preserve-status[always exit with the same status as command even if it times out]' \
  "--foreground[don't propagate timeout to the command children]" \
  '(-s --signal)'{-s,--signal}'[specify the signal to send on timeout]:signal:_signals' \
  '(-k --kill-after)'{-k,--kill-after}'[followup first signal with SIGKILL if command persists after specified time]:time' \
  '1: :_guard "[0-9.]#([smhd]|)" duration' \
  '*:::command:_normal'
debug log:

solving d0ff085bb ...
found d0ff085bb in https://git.vuxu.org/mirror/zsh/

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).