1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
| | #autoload
# The option `-e' if given as the first argument says that we should
# complete only external commands and executable files. This and a
# `-' as the first argument is then removed from the arguments.
local args defs expl ffilt verbose
zstyle -t ":completion:${curcontext}:commands" rehash && rehash
zstyle -t ":completion:${curcontext}:functions" prefix-needed && \
[[ $PREFIX != [_.]* ]] && \
ffilt='[(I)[^_.]*]'
defs=(
'commands:external command:_path_commands'
)
if [[ -n "$path[(r).]" || $PREFIX = */* ]]; then
defs+=( 'executables:executable file:_files -g \*\(-\*\)' )
else
# this is ignored but exists to facilitate the use of the fake style
_description executables expl 'executable file'
fi
if [[ "$1" = -e ]]; then
shift
elif (( ${#precommands:|builtin_precommands} )); then
# precommand excludes internal options below
else
[[ "$1" = - ]] && shift
defs=( "$defs[@]"
'builtins:builtin command:compadd -Qk builtins'
"functions:shell function:compadd -k 'functions$ffilt'"
'suffix-aliases:suffix alias:_suffix_alias_files'
'reserved-words:reserved word:compadd -Qk reswords'
'jobs:: _jobs -t'
'parameters:: _parameters -g "^*(readonly|association)*" -qS= -r "\n\t\- =[+"'
'parameters:: _parameters -g "*association*~*readonly*" -qS\[ -r "\n\t\- =[+"'
)
if zstyle -T ":completion:${curcontext}:aliases" verbose; then
printf -v verbose %s:%s\ ${(@q+)${(kv)aliases}[@]//\:/\\:}
defs+=( "aliases:alias:(( $verbose ))" )
else
defs+=( 'aliases:alias:compadd -Qk aliases' )
fi
fi
args=( "$@" )
local -a cmdpath
zstyle -a ":completion:${curcontext}" command-path cmdpath
# Using the current PATH doesn't necessarily make sense when completing commands
# to tools like sudo, which might set a different one. A common issue is that
# /**/sbin appear in the PATH used by the tool, but not in the one used by the
# unprivileged user who calls it. To do the right thing in the most common
# cases, we'll simply ensure that the sbin variants always appear here when not
# otherwise overridden (bash-completion's _sudo does something similar)
if (( ! $#cmdpath && $#_comp_priv_prefix )); then
cmdpath=( $path ${path/%\/bin//sbin} )
cmdpath=( ${(u)^cmdpath}(/-N) )
fi
if (( $#cmdpath )); then
local -a +h path
local -A +h commands
path=( $cmdpath:A )
fi
_alternative -O args "$defs[@]"
|