zsh-workers
 help / color / mirror / code / Atom feed
d72a4ee6258da4c60905382eb93e16e8bf5c63b2 blob 2540 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
 
#compdef script scriptreplay

local args hlp="-h --help -V --version"

if [[ $service = scriptreplay ]]; then
  _arguments -S -s \
    "(1 -t --timing $hlp)"{-t+,--timing=}'[specify file containing timing output]:timing file:_files' \
    "(2 -s --typescript $hlp)"{-s+,--typescript=}'[specify file containing terminal output]:typescript file:_files' \
    "(3 -d --divisor $hlp)"{-d+,--divisor=}'[speed up replay]:factor' \
    "(-m --maxdelay $hlp)"{-m+,--maxdelay=}'[set maximum delay between updates]:delay (seconds)' \
    '(- *)'{-h,--help}'[display help information]' \
    '(- *)'{-V,--version}'[display version information]' \
    "(-t --timing $hlp):timing file:_files" \
    "(-s --typescript $hlp):typescript file:_files" \
    "(-d --divisor $hlp): :_guard '[0-9.]#' 'timing divisor'"
  return
fi

case $OSTYPE in
  linux*)
    args=( -S
      "(-a --append $hlp)"{-a,--append}'[append output]'
      "(-c --command $hlp)"{-c,--command=}'[run specified command instead of a shell]:command:_cmdstring'
      "(-e --return $hlp)"{-e,--return}'[return exit status of the child process]'
      "(-f --flush $hlp)"{-f,--flush}'[flush output after each write]'
      "($hlp)--force[use output file even when it is a link]"
      '(-o --output-limit)'{-o+,--output-limit=}'[terminate if output files exceed specified size]:size (bytes)'
      "(-q --quiet $hlp)"{-q,--quiet}'[be quiet]'
      "(-t --timing $hlp)"{-t-,--timing=-}'[output timing data]::timing file:_files'
      '(- 1)'{-h,--help}'[display help information]'
      '(- 1)'{-V,--version}'[display version information]'
    )
  ;;
  darwin*|dragonfly*|netbsd*|freebsd*)
    args=(
      '-q[be quiet: suppress display of starting and ending lines]'
    )
  ;|
  netbsd*|freebsd*)
    args+=(
      '(-a -r -k)-d[suppress sleeps when playing back a session]'
      '(-a -r -k -t)-p[play back a recorded session]'
      '(-d -p)-r[record a session with input, output and timing data]'
    )
  ;|
  netbsd*|openbsd*)
    args+=(
      '-c[run specified command instead of a shell]:command:_cmdstring'
    )
  ;|
  netbsd*)
    args+=( '-f[flush output after each write]' )
  ;|
  freebsd*)
    args+=(
      '-f[use filemon(4)]'
    )
  ;|
  darwin*|dragonfly*|freebsd*)
    args+=(
      '-t+[specify interval of data flushing]:interval (seconds)'
      '-k[log keys sent to the program as well as output]'
      '*:::arguments: _normal'
    )
  ;|
  *)
    args+=(
      '(-p -d)-a[append output]'
    )
  ;;
esac

_arguments -s $args \
  "($hlp):typescript file:_files"
debug log:

solving d72a4ee62 ...
found d72a4ee62 in https://inbox.vuxu.org/zsh-workers/52343-1541926649.807710@PpMv.8Fc5.RHuT/
found dfe57a796 in https://git.vuxu.org/mirror/zsh/
preparing index
index prepared:
100644 dfe57a7964cd59dd9c11996d9484b9d4c3e318b9	Completion/Unix/Command/_script

applying [1/1] https://inbox.vuxu.org/zsh-workers/52343-1541926649.807710@PpMv.8Fc5.RHuT/
diff --git a/Completion/Unix/Command/_script b/Completion/Unix/Command/_script
index dfe57a796..d72a4ee62 100644

Checking patch Completion/Unix/Command/_script...
Applied patch Completion/Unix/Command/_script cleanly.

index at:
100644 d72a4ee6258da4c60905382eb93e16e8bf5c63b2	Completion/Unix/Command/_script

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).