f3a809f42ec3ac77dc168b44ec3d15f4b2a64a95 blob 1063 bytes (raw)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
| | #compdef -k complete-word \C-x?
eval "$_comp_setup"
(( $+_debug_count )) || integer -g _debug_count
local tmp=${TMPPREFIX}${$}${words[1]:t}$[++_debug_count]
local pager w="${(qq)words}"
integer debug_fd=-1
{
if [[ -t 2 ]]; then
zmodload -F zsh/files b:zf_ln 2>/dev/null &&
zf_ln -fn =(<<<'') $tmp &&
exec {debug_fd}>&2 2>| $tmp
fi
local -a debug_indent
() {
setopt localoptions no_ignorebraces
debug_indent=( '%'{3..20}'(e. .)' )
}
local PS4="${(j::)debug_indent}+%N:%i> "
setopt xtrace
: $ZSH_NAME $ZSH_VERSION
${1:-_main_complete}
integer ret=$?
unsetopt xtrace
if (( debug_fd != -1 )); then
zstyle -s ':completion:complete-debug::::' pager pager
print -sR "${pager:-${PAGER:-${VISUAL:-${EDITOR:-more}}}} ${(q)tmp} ;: $w"
_message -r "Trace output left in $tmp (up-history to view)"
if [[ $compstate[nmatches] -le 1 && $compstate[list] != *force* ]]; then
compstate[list]='list force messages'
fi
fi
} always {
(( debug_fd != -1 )) && exec 2>&$debug_fd {debug_fd}>&-
}
return ret
|
debug log:
solving f3a809f42 ...
found f3a809f42 in https://inbox.vuxu.org/zsh-workers/0404aac5-7212-2c10-7202-60400fc4222d@gmx.com/
found 94fd4accd in https://git.vuxu.org/mirror/zsh/
preparing index
index prepared:
100644 94fd4accdaa377d599e84fe423e53590d619e35e Completion/Base/Widget/_complete_debug
applying [1/1] https://inbox.vuxu.org/zsh-workers/0404aac5-7212-2c10-7202-60400fc4222d@gmx.com/
diff --git a/Completion/Base/Widget/_complete_debug b/Completion/Base/Widget/_complete_debug
index 94fd4accd..f3a809f42 100644
Checking patch Completion/Base/Widget/_complete_debug...
Applied patch Completion/Base/Widget/_complete_debug cleanly.
index at:
100644 f3a809f42ec3ac77dc168b44ec3d15f4b2a64a95 Completion/Base/Widget/_complete_debug
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).