New make.bat, give it a try

New make.bat, give it a try

[Frank Schmitt]

[-- Attachment #1: Type: text/plain, Size: 481 bytes --]

Hello

I just finished a new make.bat file which should work with both emacs
and xemacs and emulate the ./configure; make circle better than the old
one.

I'd be really interested in your experiences with it, I have tested it
with Emacs 21.3 and XEmacs 21.4.11 under Windows XP, therefor I'd be
especially interested if everything works under Win 9x, too.

WARNING: This is experimental stuff, backup everything before you start
it and don't blame me if it eats your children :-)


[-- Attachment #2: New make.bat --]
[-- Type: application/octet-stream, Size: 4527 bytes --]

@echo off

rem Written by Frank Schmitt <ich@frank-schmitt.net>
rem based on the work by David Charlap (shamino@writeme.com)
rem .
rem Clear PWD so emacs doesn't get confused
set GNUS_PWD_SAVE=%PWD%
set PWD=

if "%1" == "" goto usage

rem Emacs 20.7 no longer includes emacs.bat. Use emacs.exe if the batch file is
rem not present -- this also fixes the problem about too many parameters on Win9x.
if exist %1\emacs.bat goto ebat
if exist %1\emacs.exe goto eexe
if exist %1\xemacs.exe goto xexe
goto noemacs

:ebat
set EMACS=emacs.bat
set GNUS_INFO_DIR=%1\..\info
set GNUS_LISP_DIR=%1\..\lisp\gnus
set GNUS_ETC_DIR=%1\..\lisp\gnus
echo Using emacs.bat
goto lisp

:eexe
set EMACS=emacs.exe
set GNUS_INFO_DIR=%1\..\info
set GNUS_LISP_DIR=%1\..\lisp\gnus
set GNUS_ETC_DIR=%1\..\lisp\gnus
echo Using emacs.exe
goto lisp
      
:xexe      
set EMACS=xemacs.exe
set GNUS_INFO_DIR=%1\..\..\xemacs-packages\info
set GNUS_LISP_DIR=%1\..\..\xemacs-packages\lisp\gnus
set GNUS_ETC_DIR=%1\..\..\xemacs-packages\etc
echo Using xemacs.exe   
goto lisp

:lisp
set EMACSBATCH=call %1\%EMACS% -no-site-file -batch -q
cd lisp
if exist gnus-load.el del gnus-load.el
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-make-cus-load .
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-make-auto-load .
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-make-load
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-compile
if not "%2" == "/copy" goto infotest
if not exist %GNUS_LISP_DIR% mkdir %GNUS_LISP_DIR%
attrib -r %GNUS_LISP_DIR%\*
copy *.el* %GNUS_LISP_DIR%
goto infotest

:infotest
cd ..\texi
if exist sieve del sieve
makeinfo sieve.texi
if exist sieve goto minfo 
REM It seems that makeinfo isn't available
set EMACSINFO=%EMACSBATCH% -l infohack.el -f batch-makeinfo
echo Using infohack.el, if you've got makeinfo.exe put in in PATH
goto info

:minfo
set EMACSINFO=makeinfo  
echo Using makeinfo
goto info

:info
%EMACSINFO% message.texi
%EMACSINFO% emacs-mime.texi
%EMACSINFO% gnus.texi
%EMACSINFO% sieve.texi
%EMACSINFO% pgg.texi
if not "%2" == "/copy" goto nocopy
if not exist %GNUS_INFO_DIR% mkdir %GNUS_INFO_DIR%
copy gnus       %GNUS_INFO_DIR%
copy gnus-?     %GNUS_INFO_DIR%
copy gnus-??    %GNUS_INFO_DIR%
copy message    %GNUS_INFO_DIR%
copy message-?  %GNUS_INFO_DIR%
copy emacs-mime %GNUS_INFO_DIR%
copy sieve      %GNUS_INFO_DIR%
copy pgg.info   %GNUS_INFO_DIR%
echo Maybe you should add the following lines to %GNUS_INFO_DIR%\dir:
echo.
echo * PGG: (pgg).		Emacs interface to various PGP implementations.
echo * Sieve: (sieve).	Managing Sieve scripts in Emacs.
echo.

:etc
cd ..\etc
if not exist %GNUS_ETC_DIR% mkdir %GNUS_ETC_DIR%
copy gnus-tut.txt %GNUS_ETC_DIR%
if not exist %GNUS_ETC_DIR%\gnus mkdir %GNUS_ETC_DIR%\gnus
attrib -r %GNUS_ETC_DIR%\gnus\*
copy .\gnus\* %GNUS_ETC_DIR%\gnus\
if not exist %GNUS_ETC_DIR%\smilies mkdir %GNUS_ETC_DIR%\smilies
attrib -r %GNUS_ETC_DIR%\smilies\*
copy .\smilies\* %GNUS_ETC_DIR%\smilies\
goto done

:nocopy
echo You chose not to copy the files, therefore you should add the 
echo following lines to the TOP of your [X]emacs customization file:
echo.
echo (add-to-list 'load-path "c:\Path\to\gnus\lisp")
echo (if (featurep 'xemacs)
echo     (add-to-list 'Info-directory-list "c:/Path/to/gnus/texi/")
echo   (add-to-list 'Info-default-directory-list "c:/Path/to/gnus/texi/")
echo.
echo Replace c:/Path/to/gnus with the Path where your new Gnus is (that's here
echo and yes, you've got to use forward slashes).

:done
cd ..
goto end

:noemacs
echo Unable to find emacs.exe or xemacs.exe on the path you specified!
echo. 
goto usage

:usage
echo Usage: make.bat :emacs-dir: [/copy]
echo.
echo where: :emacs-dir: is the directory your emacs.exe respectively xemacs.exe
echo        resides in, e.g. G:\Programme\XEmacs\XEmacs-21.4.11\i586-pc-win32\
echo        or G:\Emacs\bin
echo        /copy indicates that the compiled files should be copied to your
echo             emacs lisp, info, and etc directories
echo        WARNING: This means that your old Gnus will be overridden!
echo.
echo Note: If you have Emacs/w3 you should set the environment variable 
echo       W3DIR to the directory where w3 is installed eg.
echo                 set W3DIR=d:\lisp\w3-4.0pre46\lisp

rem Restore PWD so whoever called this batch file doesn't get confused
set PWD=%GNUS_PWD_SAVE%
set GNUS_PWD_SAVE=
set EMACSBATCH=
set GNUS_LISP_DIR=
set GNUS_INFO_DIR=
set GNUS_ETC_DIR=
:end

[-- Attachment #3: Type: text/plain, Size: 158 bytes --]



-- 
One Ring to rule them all, One Ring to find them,
One Ring to bring them all and in the darkness bind them
In the Land of Mordor where the Shadows lie.

Re: New make.bat, give it a try

[Peter Wu]

Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:

> Hello
>
> I just finished a new make.bat file which should work with both emacs
> and xemacs and emulate the ./configure; make circle better than the old
> one.

Is this new make.bat included in the Oort Gnus daily snapshot?

-- 
Peter Wu
Powered by FreeBSD 4.8-RC

This posting is provided "AS IS" with no warranties, and confers no rights.

Re: New make.bat, give it a try

[Frank Schmitt]

Peter Wu <peterwu@canada.com> writes:

> Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:
>>
>> I just finished a new make.bat file which should work with both emacs
>> and xemacs and emulate the ./configure; make circle better than the old
>> one.
>
> Is this new make.bat included in the Oort Gnus daily snapshot?

No, it was attached to the posting.

-- 
One Ring to rule them all, One Ring to find them,
One Ring to bring them all and in the darkness bind them
In the Land of Mordor where the Shadows lie.

Re: New make.bat, give it a try

[Han Pilmeyer]

>>>>> "Frank" == Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:

Frank> I just finished a new make.bat file which should work with both emacs
Frank> and xemacs and emulate the ./configure; make circle better than the old
Frank> one.

Frank> I'd be really interested in your experiences with it, I have tested it
Frank> with Emacs 21.3 and XEmacs 21.4.11 under Windows XP, therefor I'd be
Frank> especially interested if everything works under Win 9x, too.

I've tried it (good excuse to install the latest Gnus snapshot) and
it seems to work well. Much better than the original version.

I have a few small nits to pick though:
- I usually install Gnus in site-packages instead of xemacs-packages
  (where the original lives). Could you make that an option perhaps?
- Is the message about adding PGG and Sieve still necessary? It seems
  to have copied those files anyway.
- The message displayed if you do not have makeinfo installed says "in
  in PATH".

Frank> WARNING: This is experimental stuff, backup everything before you start
Frank> it and don't blame me if it eats your children :-)

It didn't eat my kids! :-)

-- 
-- Han Pilmeyer, email: han@zk3.dec.compaq.hp.com                            --
--	    Hewlett-Packard Company - UNIX Support Engineering Group         --
--         Answers are the easy part, questions raise the doubt   - JB       --
-- All opinions are those of the author, not of Hewlett-Packard Company!     --

Re: New make.bat, give it a try

[Frank Schmitt]

Han Pilmeyer <han@zk3.dec.com> writes:

> I've tried it (good excuse to install the latest Gnus snapshot) and
> it seems to work well. Much better than the original version.

Glad to hear. Could you tell me which Operating System you used?

> I have a few small nits to pick though:
> - I usually install Gnus in site-packages instead of xemacs-packages
>   (where the original lives). Could you make that an option perhaps?

Perhaps this should be the default? I'll ask the XEmacs people what
they think.

> - Is the message about adding PGG and Sieve still necessary? It seems
>   to have copied those files anyway.

Yes, it copies them but doesn't add them to the dir file (the task
which is done by install-info on Unix systems)

> - The message displayed if you do not have makeinfo installed says "in
>   in PATH".

Fixed.

-- 
One Ring to rule them all, One Ring to find them,
One Ring to bring them all and in the darkness bind them
In the Land of Mordor where the Shadows lie.

Even newer make.bat (was: New make.bat, give it a try)

[Frank Schmitt]

[-- Attachment #1: Type: text/plain, Size: 212 bytes --]

Hello

I just integrated the changes suggested by Han. Gnus is now installed
in site-packages under XEmacs, there are more checks if the directories
we will copy files to exist and I've fixed some misspellings.


[-- Attachment #2: Gnus make batch file --]
[-- Type: application/octet-stream, Size: 4882 bytes --]

@echo off

rem Written by Frank Schmitt <ich@frank-schmitt.net>
rem based on the work by David Charlap (shamino@writeme.com)
rem .
rem Clear PWD so emacs doesn't get confused
set GNUS_PWD_SAVE=%PWD%
set PWD=

if "%1" == "" goto usage

rem Emacs 20.7 no longer includes emacs.bat. Use emacs.exe if the batch file is
rem not present -- this also fixes the problem about too many parameters on Win9x.
if exist %1\emacs.bat goto ebat
if exist %1\emacs.exe goto eexe
if exist %1\xemacs.exe goto xexe
goto noemacs

:ebat
set EMACS=emacs.bat
set GNUS_INFO_DIR=%1\..\info
set GNUS_LISP_DIR=%1\..\lisp\gnus
set GNUS_ETC_DIR=%1\..\lisp\gnus
echo Using emacs.bat
goto lisp

:eexe
set EMACS=emacs.exe
set GNUS_INFO_DIR=%1\..\info
set GNUS_LISP_DIR=%1\..\lisp\gnus
set GNUS_ETC_DIR=%1\..\lisp\gnus
echo Using emacs.exe
goto lisp
      
:xexe      
set EMACS=xemacs.exe
if not "%2" == "/copy" goto xexenocopy
if not exist %1\..\..\site-packages\info mkdir %1\..\..\site-packages\info
if not exist %1\..\..\site-packages\lisp mkdir %1\..\..\site-packages\lisp
if not exist %1\..\..\site-packages\lisp\gnus mkdir %1\..\..\site-packages\lisp\gnus
if not exist %1\..\..\site-packages\etc mkdir %1\..\..\site-packages\etc
:xexenocopy
set GNUS_INFO_DIR=%1\..\..\site-packages\info
set GNUS_LISP_DIR=%1\..\..\site-packages\lisp\gnus
set GNUS_ETC_DIR=%1\..\..\site-packages\etc
echo Using xemacs.exe   
goto lisp

:lisp
set EMACSBATCH=call %1\%EMACS% -no-site-file -batch -q
cd lisp
if exist gnus-load.el del gnus-load.el
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-make-cus-load .
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-make-auto-load .
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-make-load
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-compile
if not "%2" == "/copy" goto infotest
if not exist %GNUS_LISP_DIR% mkdir %GNUS_LISP_DIR%
attrib -r %GNUS_LISP_DIR%\*
copy *.el* %GNUS_LISP_DIR%
goto infotest

:infotest
cd ..\texi
if exist sieve del sieve
makeinfo sieve.texi
if exist sieve goto minfo 
REM It seems that makeinfo isn't available
set EMACSINFO=%EMACSBATCH% -l infohack.el -f batch-makeinfo
echo Using infohack.el, if you've got makeinfo.exe put in PATH
goto info

:minfo
set EMACSINFO=makeinfo  
echo Using makeinfo
goto info

:info
%EMACSINFO% message.texi
%EMACSINFO% emacs-mime.texi
%EMACSINFO% gnus.texi
%EMACSINFO% sieve.texi
%EMACSINFO% pgg.texi
if not "%2" == "/copy" goto nocopy
if not exist %GNUS_INFO_DIR% mkdir %GNUS_INFO_DIR%
copy gnus       %GNUS_INFO_DIR%
copy gnus-?     %GNUS_INFO_DIR%
copy gnus-??    %GNUS_INFO_DIR%
copy message    %GNUS_INFO_DIR%
copy message-?  %GNUS_INFO_DIR%
copy emacs-mime %GNUS_INFO_DIR%
copy sieve      %GNUS_INFO_DIR%
copy pgg.info   %GNUS_INFO_DIR%
echo Maybe you should add the following lines to %GNUS_INFO_DIR%\dir:
echo.
echo * PGG: (pgg).	Emacs interface to various PGP implementations.
echo * Sieve: (sieve).	Managing Sieve scripts in Emacs.
echo.

:etc
cd ..\etc
if not exist %GNUS_ETC_DIR% mkdir %GNUS_ETC_DIR%
copy gnus-tut.txt %GNUS_ETC_DIR%
if not exist %GNUS_ETC_DIR%\gnus mkdir %GNUS_ETC_DIR%\gnus
attrib -r %GNUS_ETC_DIR%\gnus\*
copy .\gnus\* %GNUS_ETC_DIR%\gnus\
if not exist %GNUS_ETC_DIR%\smilies mkdir %GNUS_ETC_DIR%\smilies
attrib -r %GNUS_ETC_DIR%\smilies\*
copy .\smilies\* %GNUS_ETC_DIR%\smilies\
goto done

:nocopy
echo You chose not to copy the files, therefore you should add the 
echo following lines to the TOP of your [X]emacs customization file:
echo.
echo (add-to-list 'load-path "c:/Path/to/gnus/lisp")
echo (if (featurep 'xemacs)
echo     (add-to-list 'Info-directory-list "c:/Path/to/gnus/texi/")
echo   (add-to-list 'Info-default-directory-list "c:/Path/to/gnus/texi/")
echo.
echo Replace c:/Path/to/gnus with the Path where your new Gnus is (that's here
echo and yes, you've got to use forward slashes).

:done
cd ..
goto end

:noemacs
echo Unable to find emacs.exe or xemacs.exe on the path you specified!
echo. 
goto usage

:usage
echo Usage: make.bat :emacs-dir: [/copy]
echo.
echo where: :emacs-dir: is the directory your emacs.exe respectively xemacs.exe
echo        resides in, e.g. G:\Programme\XEmacs\XEmacs-21.4.11\i586-pc-win32\
echo        or G:\Emacs\bin
echo        /copy indicates that the compiled files should be copied to your
echo             emacs lisp, info, and etc directories
echo        WARNING: This means that your old Gnus will be overridden!
echo.
echo Note: If you have Emacs/w3 you should set the environment variable 
echo       W3DIR to the directory where w3 is installed eg.
echo                 set W3DIR=d:\lisp\w3-4.0pre46\lisp

rem Restore PWD so whoever called this batch file doesn't get confused
set PWD=%GNUS_PWD_SAVE%
set GNUS_PWD_SAVE=
set EMACSBATCH=
set GNUS_LISP_DIR=
set GNUS_INFO_DIR=
set GNUS_ETC_DIR=
:end

[-- Attachment #3: Type: text/plain, Size: 158 bytes --]



-- 
One Ring to rule them all, One Ring to find them,
One Ring to bring them all and in the darkness bind them
In the Land of Mordor where the Shadows lie.

Re: New make.bat, give it a try

[Norbert Koch]

Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:

>> I have a few small nits to pick though:
>> - I usually install Gnus in site-packages instead of xemacs-packages
>>   (where the original lives). Could you make that an option perhaps?
>
> Perhaps this should be the default? I'll ask the XEmacs people what
> they think.

package-release-manager-hat="on"

Yes, I think, this is correct.  Packages that people the standard tree
are or should be pre-tested.  If you installed using the UNIX
Makefile, the package would also go to the site-packages, cf the
variable lispdir.

package-release-manager-hat="off"

Also, I think it's a good thing, that you still have a working copy
around in your standard package tree :-)

norbert.

Re: New make.bat, give it a try

[Han Pilmeyer]

>>>>> "Frank" == Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:

Frank> Glad to hear. Could you tell me which Operating System you used?

Windows XP (unfortunately).

I'm still using Wes's smiley package. So I usually forget to put the
correct version in the sources tree. This usually means I have to
build again. In the version of make.bat I used before, I deleted *.elc
before the recompile. Would this make sense in general?

Cheers.
-- 
-- Han Pilmeyer, email: han@zk3.dec.compaq.hp.com                            --
--	    Hewlett-Packard Company - UNIX Support Engineering Group         --
--         Answers are the easy part, questions raise the doubt   - JB       --
-- All opinions are those of the author, not of Hewlett-Packard Company!     --

Re: New make.bat, give it a try

[Frank Schmitt]

Peter Wu writes: 

> I mean whether this new make.bat will be included in the snapshot
> tarball. Will it be distributed with Oort Gnus?

My idea was to wait until some people have reported that it works
for them and then ask Larsi (or somebody else with CVS write access)
to delete make-x.bat and replace the old make.bat with the new one. 

BTW: Did you try it and if it did, worked it? 

MFG Frank 

Re: New make.bat, give it a try

[Frank Schmitt]

Han Pilmeyer <han@zk3.dec.com> writes:

>>>>>> "Frank" == Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:
>
> Frank> Glad to hear. Could you tell me which Operating System you used?
>
> Windows XP (unfortunately).
>
> I'm still using Wes's smiley package. So I usually forget to put the
> correct version in the sources tree. This usually means I have to
> build again. In the version of make.bat I used before, I deleted *.elc
> before the recompile. Would this make sense in general?

Sorry, I don't really understand what you mean. You use an other
smiley.el and want to know if you've got to recompile everything when
changing smiley.el?

If this is it, I don't really know, but I think this shouldn't be
necessary. In general, all .el files which are newer than the
corresponding .elc file are compiled, the rest isn't, then all el and
elc files are copied (if you specified /copy).

-- 
One Ring to rule them all, One Ring to find them,
One Ring to bring them all and in the darkness bind them
In the Land of Mordor where the Shadows lie.

Re: New make.bat, give it a try

[Han Pilmeyer]

>>>>> "Frank" == Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:

Frank> Sorry, I don't really understand what you mean. You use an other
Frank> smiley.el and want to know if you've got to recompile everything when
Frank> changing smiley.el?

Frank> If this is it, I don't really know, but I think this shouldn't be
Frank> necessary. In general, all .el files which are newer than the
Frank> corresponding .elc file are compiled, the rest isn't, then all el and
Frank> elc files are copied (if you specified /copy).

It's just a procedural error in my part. I run the script and
everything compiles just fine and is copied to the proper Gnus
directories. Then I find out I can't display messages any longer,
since I'm still set up for the other "old" smiley.el. So I copy my old
smiley.el (with an old date) into the lisp directory and compile
again. Bit it still doesn't work, since there was a new smiley.elc. To
prevent this I added a delete of *.elc to the script.

But perhaps this is too specific to my situations and others don't
like the overhead.

Cheers.
-- 
-- Han Pilmeyer, email: han@zk3.dec.compaq.hp.com                            --
--	    Hewlett-Packard Company - UNIX Support Engineering Group         --
--         Answers are the easy part, questions raise the doubt   - JB       --
-- All opinions are those of the author, not of Hewlett-Packard Company!     --

Re: New make.bat, give it a try

[Frank Schmitt]

Han Pilmeyer <han@zk3.dec.com> writes:

> It's just a procedural error in my part. I run the script and
> everything compiles just fine and is copied to the proper Gnus
> directories. Then I find out I can't display messages any longer,
> since I'm still set up for the other "old" smiley.el. So I copy my old
> smiley.el (with an old date) into the lisp directory and compile
> again. Bit it still doesn't work, since there was a new smiley.elc. To
> prevent this I added a delete of *.elc to the script.

Ah, I now understand. Indeed an option to recompile everything could be
useful (for example for people who use both Emacs and XEmacs) however
introducing more (optional) options would mean a bit of work and saying
del lisp/*.elc isn't much work. I'll look if it can easily be done.

BTW: For your problem with smiley.el: Why don't you put your preferred
smiley.el in e.g. ~/mylisp and say

(add-to-list 'load-path "~/mylisp")

at the top of ~/.emacs, then this file would shadow the new Gnus
smiley.el and your hassle is gone.

-- 
One Ring to rule them all, One Ring to find them,
One Ring to bring them all and in the darkness bind them
In the Land of Mordor where the Shadows lie.

Re: New make.bat, give it a try

[Han Pilmeyer]

>>>>> "Frank" == Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:

Frank> BTW: For your problem with smiley.el: Why don't you put your preferred
Frank> smiley.el in e.g. ~/mylisp and say

Yes. I set that up months (if not years) ago, but ran into some
problem and never completed it. So I took this as an excuse to make
that work.

To test it, I had to build another Gnus environment from scratch and
used your latest incarnation of the make script. It works perfect now
for me. Thanks!

Cheers.
-- 
-- Han Pilmeyer, email: han@zk3.dec.compaq.hp.com                            --
--	    Hewlett-Packard Company - UNIX Support Engineering Group         --
--         Answers are the easy part, questions raise the doubt   - JB       --
-- All opinions are those of the author, not of Hewlett-Packard Company!     --

Re: Even newer make.bat

[Frank Haun]

Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:

> I just integrated the changes suggested by Han. Gnus is now installed
> in site-packages under XEmacs, there are more checks if the directories
> we will copy files to exist and I've fixed some misspellings.

| GNU Emacs 21.3.50.1 (i386-mingw-nt5.0.2195)
| Oort Gnus v0.16

Note, I doesn't use the copy option.

`newmake.bat' works fine with W2K CMD, But normally I (maybe a lot of
people more) compile Gnus from the Cygwin Rxvt running a bash.

Typing »./newmake.bat RET« offers `G:\Emacs\bin' as an example. This
doesn't work. I've to type `G:\Emacs/bin' or `G:/Emacs/bin'.

Hm, on Win NT* Systems `G:/Emacs/bin' works with `command.com' and
`cmd.exe' (both tested). Unfortunately I don't know if it does on W9* or
ME. Maybe the example comes with slashes.

Next page...
\f

"Using makeinfo"

Great, thats fast.

Frank

Re: New make.bat, give it a try

[Peter Wu]

Frank Schmitt wrote:

> Peter Wu writes:
>
>> I mean whether this new make.bat will be included in the snapshot
>> tarball. Will it be distributed with Oort Gnus?
>
> My idea was to wait until some people have reported that it works
> for them and then ask Larsi (or somebody else with CVS write access)
> to delete make-x.bat and replace the old make.bat with the new one.
>
> BTW: Did you try it and if it did, worked it?

I tried to execute 'newmake C:\emacs-21.2 /copy' and got the following
prompt to ask me to use make.bat.

<newmake.bat>
Usage: make.bat :emacs-dir: [/copy]

where: :emacs-dir: is the directory your emacs.exe respectively xemacs.exe
       resides in, e.g. G:\Programme\XEmacs\XEmacs-21.4.11\i586-pc-win32\
       or G:\Emacs\bin
       /copy indicates that the compiled files should be copied to your
            emacs lisp, info, and etc directories
       WARNING: This means that your old Gnus will be overridden!

Note: If you have Emacs/w3 you should set the environment variable
      W3DIR to the directory where w3 is installed eg.
                set W3DIR=d:\lisp\w3-4.0pre46\lisp
</newmake.bat>



--
Cheers, Peter

Re: Even newer make.bat

[Frank Schmitt]

Frank Haun <pille3003@fhaun.de> writes:

> `newmake.bat' works fine with W2K CMD, But normally I (maybe a lot of
> people more) compile Gnus from the Cygwin Rxvt running a bash.
>
> Typing »./newmake.bat RET« offers `G:\Emacs\bin' as an example. This
> doesn't work. I've to type `G:\Emacs/bin' or `G:/Emacs/bin'.

I think bash (or tcsh or zsh, whatever you use) will eat the
\. newmake.bat G:\\Emacs\\bin should work however. (Or you write a
mymake.bat which consist of one line saying
newmake.bat c:\emacs\bin)

-- 
One Ring to rule them all, One Ring to find them,
One Ring to bring them all and in the darkness bind them
In the Land of Mordor where the Shadows lie.

Re: New make.bat, give it a try

[Kai Großjohann]

"Peter Wu" <peterwu@canada.com> writes:

> I tried to execute 'newmake C:\emacs-21.2 /copy' and got the following
> prompt to ask me to use make.bat.
>
> <newmake.bat>
> Usage: make.bat :emacs-dir: [/copy]
>
> where: :emacs-dir: is the directory your emacs.exe respectively xemacs.exe

I guess that emacs.exe is in c:/emacs-21.2/bin, not c:/emacs-21.2.
-- 
A preposition is not a good thing to end a sentence with.

Re: Even newer make.bat

[Frank Haun]

Frank Schmitt <usereplyto@Frank-Schmitt.net> writes:

> Frank Haun <pille3003@fhaun.de> writes:
>
>> `newmake.bat' works fine with W2K CMD, But normally I (maybe a lot of
>> people more) compile Gnus from the Cygwin Rxvt running a bash.
>>
>> Typing »./newmake.bat RET« offers `G:\Emacs\bin' as an example. This
>> doesn't work. I've to type `G:\Emacs/bin' or `G:/Emacs/bin'.
>
> I think bash (or tcsh or zsh, whatever you use) will eat the
> \. newmake.bat G:\\Emacs\\bin should work however. (Or you write a
> mymake.bat which consist of one line saying
> newmake.bat c:\emacs\bin)

OK, I can live with escaping the backslashes. Thanks.

Frank

Re: New make.bat, give it a try

[Frank Haun]

"Peter Wu" <peterwu@canada.com> writes:

> I tried to execute 'newmake C:\emacs-21.2 /copy' and got the following
> prompt to ask me to use make.bat.
>
> <newmake.bat>
> Usage: make.bat :emacs-dir: [/copy]
>
> where: :emacs-dir: is the directory your emacs.exe respectively xemacs.exe
>        resides in, e.g. G:\Programme\XEmacs\XEmacs-21.4.11\i586-pc-win32\
>        or G:\Emacs\bin
                    ^^^^

Therefore you've to say

    »newmake C:\emacs-21.2\bin /copy«

Frank

Re: New make.bat, give it a try

[Peter Wu]

Frank Haun <pille3003@fhaun.de> writes:

> "Peter Wu" <peterwu@canada.com> writes:
>
>> I tried to execute 'newmake C:\emacs-21.2 /copy' and got the following
>> prompt to ask me to use make.bat.
>>
>> <newmake.bat>
>> Usage: make.bat :emacs-dir: [/copy]
>>
>> where: :emacs-dir: is the directory your emacs.exe respectively xemacs.exe
>>        resides in, e.g. G:\Programme\XEmacs\XEmacs-21.4.11\i586-pc-win32\
>>        or G:\Emacs\bin
>                     ^^^^
>
> Therefore you've to say
>
>     »newmake C:\emacs-21.2\bin /copy«

Sorry for my carelessness. :(

Your newmake.bat works fine but I don't see anything different from the
make.bat included in the tarball. 

-- 
Peter Wu
Powered by FreeBSD 4.8-RC

This posting is provided "AS IS" with no warranties, and confers no rights.

Re: New make.bat, give it a try

[Frank Haun]

Peter Wu <peterwu@canada.com> writes:

> Your newmake.bat works fine

Frank Schmitt wrote it.

> but I don't see anything different from the make.bat included in the
> tarball.

Have a look »diff make.bat newmake.bat«

And more, if available `makeinfo' is used, that's very fast and further
it works with Emacs and XEmacs.

Frank

Re: Even newer make.bat

[Reiner Steib]

On Thu, Mar 06 2003, Frank Schmitt wrote:

> :usage
> echo Usage: make.bat :emacs-dir: [/copy]
> echo.
> echo where: :emacs-dir: is the directory your emacs.exe respectively xemacs.exe
> echo        resides in, e.g. G:\Programme\XEmacs\XEmacs-21.4.11\i586-pc-win32\
> echo        or G:\Emacs\bin

Maybe ":emacs-dir:" should be changed to ":exe-dir:" (or ":bin-dir:")
or something similar?  (Usually, emacs-dir is associated with the root
directory of the Emacs installation.)

Bye, Reiner.
-- 
       ,,,
      (o o)
---ooO-(_)-Ooo--- PGP key available via WWW   http://rsteib.home.pages.de/

Re: Even newer make.bat

[Frank Schmitt]

Reiner Steib <4.uce.03.r.s@nurfuerspam.de> writes:

> On Thu, Mar 06 2003, Frank Schmitt wrote:
>
>> :usage
>> echo Usage: make.bat :emacs-dir: [/copy]
>> echo.
>> echo where: :emacs-dir: is the directory your emacs.exe respectively xemacs.exe
>> echo        resides in, e.g. G:\Programme\XEmacs\XEmacs-21.4.11\i586-pc-win32\
>> echo        or G:\Emacs\bin
>
> Maybe ":emacs-dir:" should be changed to ":exe-dir:" (or ":bin-dir:")
> or something similar?  (Usually, emacs-dir is associated with the root
> directory of the Emacs installation.)

Good idea, I changed it to :[X]Emacs-exe-dir:.

-- 
One Ring to rule them all, One Ring to find them,
One Ring to bring them all and in the darkness bind them
In the Land of Mordor where the Shadows lie.