Completing comma seprated list of option values in _atguments

Completing comma seprated list of option values in _atguments

[Borsenkow Andrej]

I must be entirely stupid but I cannot figure out how to do it. Values
must be generated on the fly not chosen from fixed array. And _values
seems to want fixed values only :(

-andrej

Re: Completing comma seprated list of option values in _atguments

[Sven Wischnowsky]

Borsenkow Andrej wrote:

> I must be entirely stupid but I cannot figure out how to do it. Values
> must be generated on the fly not chosen from fixed array. And _values
> seems to want fixed values only :(

Yes, _values is not intended for that, although it depends on how the
values are generated, of course...

We probably don't need utility functions for everything, simple
solution, not that nice, but ok when values may appear more than once:

  local expl

  compset -P '*,'
  _wanted foos expl foo compadd -qS, calculated values

More sophisticated, values may appear only once:

  local expl comps suf

  comps=(value calculation goes here)

  compset -P '*,'
  comps=( ${comps:#${~IPREFIX//,/|}} )

  if [[ $#comps -gt 1 ]]; then
    suf=(-qS,)
  else
    suf=()
  fi

  _wanted foos expl foo compadd $suf $comps

If you want to generate the matches even later, I'd suggest using the
first version with _wanted calling a utility function that builds the
matches. But if those values are the only possible matches in that
context and hence are the normal completions in that case it's
probably not worth it and the code above should be enough.


Bye
  Sven

-- 
Sven Wischnowsky                          wischnow@berkom.de

Re: Completing comma seprated list of option values in _atguments

[Borsenkow Andrej]

On Пнд, 2002-02-25 at 11:54, Sven Wischnowsky wrote:
> 
> Borsenkow Andrej wrote:
> 
> > I must be entirely stupid but I cannot figure out how to do it. Values
> > must be generated on the fly not chosen from fixed array. And _values
> > seems to want fixed values only :(
> 
> Yes, _values is not intended for that, although it depends on how the
> values are generated, of course...
> 
> We probably don't need utility functions for everything, simple
> solution, not that nice, but ok when values may appear more than once:
> 

I finally ended up with

_urpmi_media() {
    local source media brace ret=1 opt
    local -a all_sources
    local context state line
    typeset -A val_args
    while read source media brace; do
        [[ "$brace" != "{" ]] && continue
        all_sources=($all_sources $source)
    done < /etc/urpmi/urpmi.cfg
    if [[ "$service" == urpmq ]]; then
        _values -s , "urpmi media"  "$all_sources[@]" && ret=0
    else
        _wanted urpmi_media expl 'available media' \
            compadd "$@" -a -- all_sources && ret=0
    fi
    return ret
}

but may be I can omit _values just as well, besides it seems to be buggy
at this point.

thanks

-andrej

Re: Completing comma seprated list of option values in _atguments

[Oliver Kiddle]

 --- Sven Wischnowsky <wischnow@berkom.de> wrote:

>   compset -P '*,'
>   _wanted foos expl foo compadd -qS, calculated values

Though this and the example which followed it don't really handle a
suffix. I'd stick compset -S ',*' || suf=(-qS,) between those two
lines.

I'd use _values here though unless you're coming up against bugs.

Oliver


__________________________________________________
Do You Yahoo!?
Everything you'll ever need on one web page
from News and Sport to Email and Music Charts
http://uk.my.yahoo.com