random once but not twice

random once but not twice

[Emanuel Berg]

Just wrote this. Strange thing is, random-video
gives me randomized files, but not
play-random-video, which is just an interface -
or that the intention, at least :)

Can anyone figure out what is going on?

All other suggestions how to improve the code,
both style and function, is appreciated, as
always...

random-video () {
    local vid_dir=${1:-.}
    local ext=${2:-mkv}

    local vid
    local -a vids
    local num_vids
    local vid_num

    vids=("${(@f)$(ls ${vid_dir}/*.${ext})}")
    num_vids=${#vids}

    vid_num=$(( RANDOM % $num_vids + 1 ))
    vid=$vids[$vid_num]

    echo $vid
}
alias rv=random-video

play-random-video () {
    local vid_dir=${1:-/mnt-disk/mm/survivor/au/04}
    local vid
    vid=$(random-video $vid_dir)
    echo "playing $vid"
    # pl $vid # local function to omx player
}
alias prv=play-random-video

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: random once but not twice

[Mikael Magnusson]

On Sat, Nov 11, 2017 at 7:57 PM, Emanuel Berg <moasen@zoho.com> wrote:
> Just wrote this. Strange thing is, random-video
> gives me randomized files, but not
> play-random-video, which is just an interface -
> or that the intention, at least :)
>
> Can anyone figure out what is going on?
>
> All other suggestions how to improve the code,
> both style and function, is appreciated, as
> always...
>
> random-video () {
>     local vid_dir=${1:-.}
>     local ext=${2:-mkv}
>
>     local vid
>     local -a vids
>     local num_vids
>     local vid_num
>
>     vids=("${(@f)$(ls ${vid_dir}/*.${ext})}")
>     num_vids=${#vids}
>
>     vid_num=$(( RANDOM % $num_vids + 1 ))
>     vid=$vids[$vid_num]
>
>     echo $vid
> }
> alias rv=random-video
>
> play-random-video () {
>     local vid_dir=${1:-/mnt-disk/mm/survivor/au/04}
>     local vid
>     vid=$(random-video $vid_dir)
>     echo "playing $vid"
>     # pl $vid # local function to omx player
> }
> alias prv=play-random-video

The subshell in the second function ensures that the RANDOM state in
the parent shell stays the same.

-- 
Mikael Magnusson

Re: random once but not twice

[Emanuel Berg]

Mikael Magnusson wrote:

> The subshell in the second function ensures
> that the RANDOM state in the parent shell
> stays the same.

But why doesn't the next invocation produce
a new value? As in

    random-test () {
        repeat 10 echo $RANDOM
    }

    $ random-test

    9235
    18141
    28176
    10397
    14564
    21514
    2335
    31921
    7989
    8201

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: random once but not twice

[Emanuel Berg]

echo $(echo $RANDOM) # always the same

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: random once but not twice

[Emanuel Berg]

Emanuel Berg wrote:

> echo $(echo $RANDOM) # always the same

OK, I learned on #zsh@freenode that $RANDOM
doesn't do anything but is inherited from the
parent shell where there has been no access and
thus no new value.

    : $RANDOM; vid=$(random-video $vid_dir)

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: random once but not twice

[Peter Stephenson]

On Sat, 11 Nov 2017 23:46:07 +0100
Emanuel Berg <moasen@zoho.com> wrote:
> Emanuel Berg wrote:
> 
> > echo $(echo $RANDOM) # always the same
> 
> OK, I learned on #zsh@freenode that $RANDOM
> doesn't do anything but is inherited from the
> parent shell where there has been no access and
> thus no new value.
> 
>     : $RANDOM; vid=$(random-video $vid_dir)

You can also work around with the following rand48 function.

(rand48; print $REPLY)
(rand48; print $REPLY)

pws


# Genrate a 48-bit pseudo-random number as a floating point value between
# 0 and 1 in $REPLY.
#
# This version is slow but works aroud the fact that the random number
# seed doesn't propagate back from a subshell by storing the seed in
# a file.
#
# You can speicify a file name, else ${ZDOTDIR:-~}/.zsh-rand48-seeed is used,
# but if using the default be careful about simultaneous accesses from
# multipe shells.

zmodload zsh/mathfunc

local file=${1:-${ZDOTDIR:-~}/.zsh-rand48-seed}
local seed

if [[ -f $file ]]; then
  seed=$(<$file)
fi

typeset -g REPLY=$(( rand48(seed) ))

print $seed >$file

Re: random once but not twice

[Emanuel Berg]

Peter Stephenson wrote:

> You can also work around with the following
> rand48 function.
>
> (rand48; print $REPLY)
> (rand48; print $REPLY)

$ (rand48; print $REPLY)

zsh: command not found: rand48

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: random once but not twice

[Bart Schaefer]

On Sun, Nov 12, 2017 at 12:02 PM, Emanuel Berg <moasen@zoho.com> wrote:
> Peter Stephenson wrote:
>
>> You can also work around with the following
>> rand48 function.
>>
>
> zsh: command not found: rand48

The entire remainder of PWS's message, starting with "# Genrate a
48-bit pseudo-random number ...", was the implementation of a shell
script or function intended to be named 'rand48'.

Re: random once but not twice

[Emanuel Berg]

Bart Schaefer wrote:

> The entire remainder of PWS's message,
> starting with "# Genrate a 48-bit
> pseudo-random number ...", was the
> implementation of a shell script or function
> intended to be named 'rand48'.

Aha! Gotcha :)

BRB

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: random once but not twice

[Emanuel Berg]

Peter Stephenson wrote:

> You can also work around with the following
> rand48 function.
>
> (rand48; print $REPLY) (rand48; print $REPLY)

Works! Only I don't understand this syntax.
What does it do?

    seed=$(<$file)

and

    print $seed >$file

I suppose is some intentional circular
short-circuit to generate gibberish data?

BTW you could benefit from a spellchecker :)
Here is a spell-checked version of your comment

# Generate a 48-bit pseudo-random number as
# a floating point value between 0 and 1 in
# $REPLY.
#
# This version is slow but works around the fact
# that the random number seed doesn't propagate
# back from a subshell by storing the seed in
# a file.
#
# You can specify a file name, else
# ${ZDOTDIR:-~}/.zsh-rand48-seed is used, but
# if using the default be careful about
# simultaneous accesses from multiple shells.

Thanks :)

-- 
underground experts united
http://user.it.uu.se/~embe8573

Re: random once but not twice

[Bart Schaefer]

On Sun, Nov 12, 2017 at 4:15 PM, Emanuel Berg <moasen@zoho.com> wrote:
>
> Works! Only I don't understand this syntax.
> What does it do?
>
>     seed=$(<$file)

RTM:

A command enclosed in parentheses preceded by a dollar sign, like
`$(...)', or quoted with grave accents, like ``...`', is replaced with
its standard output, with any trailing newlines deleted.  If the
substitution is not enclosed in double quotes, the output is broken
into words using the IFS parameter.  The substitution `$(cat FOO)' may
be replaced by the equivalent but faster `$(<FOO)'.  In either case,
if the option GLOB_SUBST is set, the output is eligible for filename
generation.

> and
>
>     print $seed >$file
>
> I suppose is some intentional circular
> short-circuit to generate gibberish data?

The comment in the function explains this:

# This version is slow but works around the fact
# that the random number seed doesn't propagate
# back from a subshell by storing the seed in
# a file.

Re: random once but not twice

[Emanuel Berg]

Bart Schaefer wrote:

> RTM

NRN

-- 
underground experts united
http://user.it.uu.se/~embe8573