From: Bart Schaefer <schaefer@brasslantern.com>
To: Zsh Users <zsh-users@zsh.org>
Subject: Re: completion within a function
Date: Sat, 2 Jan 2021 14:24:49 -0800 [thread overview]
Message-ID: <CAH+w=7adMRpgA97=Y-m_U--HW0APgVH3Bq4Y3=Zjy9uoh_7fzg@mail.gmail.com> (raw)
In-Reply-To: <CAH+w=7bZXGvVqeftVn4FnPd+G9Y5tm+YU6yV9wkgE1vXTEVLKw@mail.gmail.com>
[-- Attachment #1: Type: text/plain, Size: 610 bytes --]
On Fri, Jan 1, 2021 at 4:27 PM Bart Schaefer <schaefer@brasslantern.com> wrote:
>
> Ahh ... because it's zpty, the cursor movements get captured along
> with everything else.
How about this?
ubuntu% complete git --
--bare
--exec-path
--git-dir
--help
--html-path
--info-path
--literal-pathspecs
--man-path
--namespace
--no-pager
--no-replace-objects
--paginate
--version
--work-tree
Earlier, Felipe wrote:
> LISTMAX=1000 # There seems to be a bug in zsh with several thousands
Could this be happening because "zpty -r" will only return up to one
megabyte of output? If not, what's the symptom of the bug?
[-- Attachment #2: complete.txt --]
[-- Type: text/plain, Size: 2111 bytes --]
#autoload
# Usage: complete commandline
#
# where "commandline" is one or more words, of which the last is the
# prefix of the desired completion. Thus:
# complete g
# completes all commands whose name starts with "g"
# complete git --
# completes all options of "git" that begin with two hyphens
# complete ls c
# completes all files in $PWD having names starting with "c"
#
# All possible completions are returned, one per line. There is a
# limit of approximately half a megabyte of total output, as a side-
# effect of vared plus the limit of one megabyte per "zpty -r".
(( $+_comps )) || { autoload -U compinit; compinit -i -D }
zmodload zsh/zpty
if ! bindkey -M __complete 2>/dev/null
then
bindkey -N __complete
zle -C __complete_all complete-word _generic
zstyle ':completion:__complete_all::::' completer _all_matches _complete
zstyle ':completion:__complete_all:*' insert true
bindkey -M __complete '^Xa' __complete_all
# bindkey -M __complete '^X?' _complete_debug
bindkey -M __complete $'\n' .accept-line
# bindkey -M __complete '^G' .send-break
__init_complete() { zle -U $'\Cxa\n' }
zle -N __init_complete
fi
completion-context() {
if (( debug )); then
print -u $debug -C 2 -a -r \
CONTEXT: ":completion:$curcontext" \
STATE: '' "${(@kv)compstate}"
fi
}
hide-vared() { compstate[vared]='' }
run-complete () {
local -a compprefuncs=(hide-vared "${(@)compprefuncs}")
vared -M __complete -i __init_complete ${${argv:+argv}:-reply}
(( ARGC )) || print -nrl -- "~~~${(@)reply}~~~"
}
debug-complete() {
local -i debug
local -a compprefuncs=(completion-context "${(@)compprefuncs}")
local -a comppostfuncs=("${(@)comppostfuncs}" completion-context)
exec {debug}>&2
complete "$@"
exec {debug}>&-
}
complete() {
(( ARGC )) || return 1
local REPLY reply=( "$@" )
zpty complete-tty run-complete
{
zpty -r complete-tty REPLY $'*~~~*~~~'
} always {
zpty -d complete-tty
}
reply=( "${(@)${(f)${${REPLY%~~~}#*~~~}}%$'\r'}" )
shift $((ARGC-1)) reply
print -lr -- "${(@)reply}"
}
(( ARGC )) && complete "$@"
next prev parent reply other threads:[~2021-01-02 22:25 UTC|newest]
Thread overview: 40+ messages / expand[flat|nested] mbox.gz Atom feed top
2020-12-29 15:24 Ray Andrews
2020-12-29 18:52 ` Bart Schaefer
2020-12-29 19:36 ` Felipe Contreras
2020-12-29 19:41 ` Roman Perepelitsa
2020-12-29 21:04 ` Ray Andrews
2020-12-29 21:21 ` Ray Andrews
2020-12-29 22:03 ` Bart Schaefer
2020-12-29 21:48 ` Bart Schaefer
2020-12-30 0:31 ` Ray Andrews
2020-12-30 4:34 ` Roman Perepelitsa
2020-12-30 16:45 ` Ray Andrews
2020-12-30 17:21 ` Felipe Contreras
2020-12-30 20:43 ` Bart Schaefer
2020-12-30 20:46 ` Bart Schaefer
2020-12-30 20:50 ` Ray Andrews
2020-12-30 21:31 ` Roman Perepelitsa
2020-12-30 22:05 ` Bart Schaefer
2020-12-30 22:18 ` Felipe Contreras
2020-12-30 23:47 ` Bart Schaefer
2020-12-31 0:08 ` Bart Schaefer
2020-12-31 0:12 ` Felipe Contreras
2020-12-31 0:30 ` Bart Schaefer
2020-12-31 0:39 ` Bart Schaefer
2020-12-31 1:04 ` Felipe Contreras
2020-12-31 21:25 ` Bart Schaefer
2021-01-01 0:12 ` Ray Andrews
2021-01-02 0:27 ` Bart Schaefer
2021-01-02 22:24 ` Bart Schaefer [this message]
2021-01-03 0:28 ` Felipe Contreras
2021-01-03 0:53 ` Bart Schaefer
2021-01-03 1:20 ` Felipe Contreras
2021-01-03 2:21 ` Bart Schaefer
2021-01-03 2:47 ` Felipe Contreras
2021-01-03 3:30 ` Bart Schaefer
2021-01-03 23:16 ` Felipe Contreras
2021-01-05 19:57 ` Bart Schaefer
2021-01-03 17:50 ` Bart Schaefer
2021-01-03 0:07 ` Felipe Contreras
2020-12-31 1:03 ` Felipe Contreras
2020-12-30 6:45 ` Bart Schaefer
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to='CAH+w=7adMRpgA97=Y-m_U--HW0APgVH3Bq4Y3=Zjy9uoh_7fzg@mail.gmail.com' \
--to=schaefer@brasslantern.com \
--cc=zsh-users@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).