Checking if a variable is exported

Checking if a variable is exported

[Martijn Dekker]

Hi all,

Does zsh have a straightforward way for a script to check if a variable
is exported? The closest-to-straightforward way I know of is to parse
the output of 'typeset -p varname', which is hairy because the output
might include various options to the command.

Thanks,

- M.

Re: Checking if a variable is exported

[Eric Cook]

On 10/21/2016 04:27 PM, Martijn Dekker wrote:
> Hi all,
> 
> Does zsh have a straightforward way for a script to check if a variable
> is exported? The closest-to-straightforward way I know of is to parse
> the output of 'typeset -p varname', which is hairy because the output
> might include various options to the command.
> 
> Thanks,
> 
> - M.
> 
if [[ ${(t)HOME} = *export* ]]; then ...

Re: Checking if a variable is exported

[Nikolay Aleksandrovich Pavlov (ZyX)]

21.10.2016, 23:34, "Martijn Dekker" <martijn@inlv.org>:
> Hi all,
>
> Does zsh have a straightforward way for a script to check if a variable
> is exported? The closest-to-straightforward way I know of is to parse
> the output of 'typeset -p varname', which is hairy because the output
> might include various options to the command.
>
> Thanks,
>
> - M.

I guess shortest version is something like

    zmodload zsh/parameter
    is_exported() {
        (( !! ${${(s.-.)parameters[$1]}[(Ie)export]} ))
    }

or

    is_exported() {
        (( !! ${${(ts.-.)${(P)1}}[(Ie)export]} ))
    }

(do not remember when (t) modifier was introduced, but AFAIR it is younger then zsh/parameter module).

---

BTW, if I use

    () { echo ${(Pts.-.)1} } PATH

I get `scalar export special` like expected. But I always get return status 1 when using

    () { (( !! ${${(Pts.-.)1}[(Ie)export]} )) } PATH

: enclosing this thing into additional ${} like

    () { echo ${${(Pts.-.)1}} } PATH

makes zsh echo $PATH value and not `scalar export special` like expected. Removing additional ${} neither works:

    () { echo ${(Pts.-.)1[1]} } PATH

echoes `s` like if it was a space-separated string and not an array.

Re: Checking if a variable is exported

[Mikael Magnusson]

On Fri, Oct 21, 2016 at 10:27 PM, Martijn Dekker <martijn@inlv.org> wrote:
> Hi all,
>
> Does zsh have a straightforward way for a script to check if a variable
> is exported? The closest-to-straightforward way I know of is to parse
> the output of 'typeset -p varname', which is hairy because the output
> might include various options to the command.

${(t)param} will contain "export".

-- 
Mikael Magnusson

Re: Checking if a variable is exported

[Bart Schaefer]

On Oct 22, 12:06am, Nikolay Aleksandrovich Pavlov (ZyX) wrote:
}
} BTW, if I use
} 
}     () { echo ${(Pts.-.)1} } PATH
}
} I get `scalar export special` like expected. But I always get return
} status 1 when using
}
}     () { (( !! ${${(Pts.-.)1}[(Ie)export]} )) } PATH

This is explained in the doc for (P):

     ... if the reference is itself nested, the expression with
     the flag is treated as if it were directly replaced by the
     parameter name.  It is an error if this nested substitution
     produces an array with more than one word.  For example, if
     `name=assoc' where the parameter assoc is an associative array,
-->  then `${${(P)name}[elt]}' refers to the element of the associative
-->  subscripted `elt'.

And then later:

     Note that, unless the `(P)' flag is present, the flags and any
     subscripts apply directly to the value of the nested substitution;
     for example, the expansion ${${foo}} behaves exactly the same as
-->  ${foo}.  When the `(P)' flag is present in a nested substitution,
-->  the other substitution rules are applied to the value _before_ it
-->  is interpreted as a name, so ${${(P)foo}} may differ from
     ${(P)foo}.

So what you need is to isolate ${(P)1} from all other parameter flags
and also separate it from the subscript expression:

torch% () { echo ${(ts.-.)${(P)1}} } PATH          
scalar export special
torch% () { echo ${${(ts.-.)${(P)1}}[(I)export]} } PATH
2