subscript not working as "I" expected it would

subscript not working as "I" expected it would

[Jim]

[-- Attachment #1: Type: text/plain, Size: 906 bytes --]

Hi everyone,

Case:  Outputting a hash from a git repository, but want it abbreviated.
   This is done totally via z-shell script, without git commands.
   Taking a bash/sed example and converting it to zsh.
Sorry if that is to much information.

With
   print -- $(<.git/${(s.: .)$(<.git/HEAD)[2]})
I get the full 40 character hash as expected
but when I tried to output the first 9 characters
  print -- ${$(<.git/${(s.: .)$(<.git/HEAD)[2]})[1,9]}
it too, returns the full 40 character hash and no warnings or error
messages.

After beating my head for a while, it dawned on me to try quoting
  print -- ${"$(<.git/${(s.: .)$(<.git/HEAD)[2]})"[1,9]}
which worked, returning the first 9 characters of the hash.

Could someone explain why the quotes are needed here so hopefully
the next time I will understand. I swear zsh quoting will drive me nuts.

Thanks for putting up with me.

Regards,

Jim Murphy

[-- Attachment #2: Type: text/html, Size: 1270 bytes --]

Re: subscript not working as "I" expected it would

[Roman Perepelitsa]

[cc:zsh-users]

On Sat, Nov 4, 2023 at 9:47 AM Roman Perepelitsa
<roman.perepelitsa@gmail.com> wrote:
>
> On Sat, Nov 4, 2023 at 8:09 AM Jim <linux.tech.guy@gmail.com> wrote:
> >
> > After beating my head for a while, it dawned on me to try quoting
> >   print -- ${"$(<.git/${(s.: .)$(<.git/HEAD)[2]})"[1,9]}
> > which worked, returning the first 9 characters of the hash.
> >
> > Could someone explain why the quotes are needed here so hopefully
> > the next time I will understand. I swear zsh quoting will drive me nuts.
>
> $(list) expands to an array. ${$(list)[N]} gives the Nth element of the array.
>
> % print -r -- ${$(print foo bar)[1]}
> foo
> % print -r -- ${$(print foo bar)[2]}
> bar
>
> $(list) can be an array with just one element but it's still an array.
> This is the case in your code snippet.
>
> "$(list)" on the other hand is a scalar. ${"$(list)"[N]} gives the Nth
> character.
>
>     % print -r -- ${"$(print foo bar)"[1]}
>     f
>     % print -r -- ${"$(print foo bar)"[2]}
>     o
>
> Roman.

Re: subscript not working as "I" expected it would

[Lawrence Velázquez]

On Sat, Nov 4, 2023, at 4:48 AM, Roman Perepelitsa wrote:
>> $(list) expands to an array. ${$(list)[N]} gives the Nth element of the array.
>>
>> % print -r -- ${$(print foo bar)[1]}
>> foo
>> % print -r -- ${$(print foo bar)[2]}
>> bar
>>
>> $(list) can be an array with just one element but it's still an array.
>> This is the case in your code snippet.
>>
>> "$(list)" on the other hand is a scalar. ${"$(list)"[N]} gives the Nth
>> character.
>>
>>     % print -r -- ${"$(print foo bar)"[1]}
>>     f
>>     % print -r -- ${"$(print foo bar)"[2]}
>>     o

Also note that subscripting occurs *before* (s) is applied, so your
(s.: .) is not doing what you think it is doing.

	% printf '<%s>' ${(s.: .)$(echo a b: c d)[2]}; echo
	<b:>
	% printf '<%s>' ${${(s.: .)"$(echo a b: c d)"}[2]}; echo
	<c d>

-- 
vq