zsh-workers
 help / color / mirror / Atom feed
* [PATCH] _basenc: a new completion for basenc
@ 2021-10-08 16:11 Jun. T
  0 siblings, 0 replies; only message in thread
From: Jun. T @ 2021-10-08 16:11 UTC (permalink / raw)
  To: zsh-workers

A simple new completion for 'basenc' command (new in GNU coreutils 8.31).


diff --git a/Completion/Linux/Command/_basenc b/Completion/Linux/Command/_basenc
new file mode 100644
index 000000000..515621aaa
--- /dev/null
+++ b/Completion/Linux/Command/_basenc
@@ -0,0 +1,30 @@
+#compdef basenc
+# based on GNU coreutils 8.32
+
+local specs=(
+  + '(type)'
+  "(info)--base64[same as 'base64' program (RFC4648 section 4)]"
+  "(info)--base64url[file- and url-safe base64 (RFC4648 section 5)]"
+  "(info)--base32[same as 'base32' program (RFC4648 section 6)]"
+  "(info)--base32hex[extended hex alphabet base32 (RFC4648 section 7)]"
+  "(info)--base16[hex encoding (RFC4648 section 8)]"
+  "(info)--base2msbf[bit string with most significant bit (msb) first]"
+  "(info)--base2lsbf[bit string with least significant bit (lsb) first]"
+  "(info)--z85[ascii85-like encoding (ZeroMQ spec-32/Z85)]"
+
+  + enc
+  '(info dec -w --wrap)'{-w+,--wrap=}"[wrap encoded lines at specified column]:number of characters (0=disable wrapping) [76]: "
+
+  + dec
+  '(info enc -d --decode)'{-d,--decode}"[decode data]"
+  '(info enc -i --ignore-garbage)'{-i,--ignore-garbage}"[when decoding, ignore non-alphabet characters]"
+
+  + info
+  "(: -)--help[display help information and exit]"
+  "(: -)--version[output version information and exit]"
+
+  + input
+  '(info)1:input file:_files'
+)
+
+_arguments -s -S : $specs





^ permalink raw reply	[flat|nested] only message in thread

only message in thread, other threads:[~2021-10-08 16:12 UTC | newest]

Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2021-10-08 16:11 [PATCH] _basenc: a new completion for basenc Jun. T

zsh-workers

This inbox may be cloned and mirrored by anyone:

	git clone --mirror https://inbox.vuxu.org/zsh-workers

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V1 zsh-workers zsh-workers/ https://inbox.vuxu.org/zsh-workers \
		zsh-workers@zsh.org
	public-inbox-index zsh-workers

Example config snippet for mirrors.
Newsgroup available over NNTP:
	nntp://inbox.vuxu.org/vuxu.archive.zsh.workers


code repositories for the project(s) associated with this inbox:

	https://git.vuxu.org/mirror/zsh/

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git