* PATCH: _piuparts
@ 2005-09-28 14:46 Clint Adams
0 siblings, 0 replies; only message in thread
From: Clint Adams @ 2005-09-28 14:46 UTC (permalink / raw)
To: zsh-workers; +Cc: Lars Wirzenius
Completion for piuparts.
Index: Completion/Debian/Command/_piuparts
===================================================================
RCS file: Completion/Debian/Command/_piuparts
diff -N Completion/Debian/Command/_piuparts
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ Completion/Debian/Command/_piuparts 28 Sep 2005 14:44:45 -0000
@@ -0,0 +1,30 @@
+#compdef piuparts
+
+local context state line
+typeset -A opt_args
+
+_arguments -s \
+ '(-a --apt)'{-a,--apt} \
+ '(-b --basetgz)'{-b,--basetgz=}':base tarball:_files' \
+ '(-d --distribution)'{-d,--distribution=}':Debian distribution:(sarge etch sid experimental)' \
+ '(-i --ignore)*'{-i,--ignore=}':file to ignore:_files' \
+ '(-I --ignore-regexp)*'{-I,--ignore-regexp=}':expression to ignore' \
+ '(-k --keep-tmpdir)'{-k,--keep-tmpdir} \
+ '(-l --log-file)'{-l,--logfile=}':log file:_files' \
+ '(-m --mirror)'{-m,--mirror=}':Debian mirror:_urls' \
+ '(-n --no-ignores)'{-n,--no-ignores} \
+ '(-p --pbuilder)'{-p,--pbuilder}'[use /var/cache/pbuilder/base.tgz]' \
+ '(-s --save)'{-s,--save=}':target tarball:_files' \
+ '(-t --tmpdir)'{-t,--tmpdir=}':temp dir:_files -/' \
+ '-V[version]' \
+ '*:package:->packages' && return 0
+
+case "$state" in
+ (packages)
+ if (( $+opt_args[-a] )); then
+ _deb_packages avail
+ else
+ _files -g '*.deb'
+ fi
+ ;;
+esac
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2005-09-28 14:46 UTC | newest]
Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2005-09-28 14:46 PATCH: _piuparts Clint Adams
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).