From: Andrey Borzenkov <arvidjaar@newmail.ru>
To: zsh-workers@sunsite.dk
Subject: Broken completion with UTF-8 description
Date: Sun, 17 Sep 2006 18:53:50 +0400 [thread overview]
Message-ID: <200609171853.57050.arvidjaar@newmail.ru> (raw)
[-- Attachment #1.1: Type: text/plain, Size: 990 bytes --]
Writing completion for kcmshell (attached); it outputs list of KDE
configuration modules together with descriptions and I have not found any way
(confirmed by KDE developers) to force descriptions in English. So far I get
the following:
{pts/1}% kcmshell --list
Доступны следующие модули:
kwalletconfig - Настройка бумажника KDE
privacy - Модуль kcontrol, очищающий нежелательные следы, оставленные
пользователем в операционной системе
...
results in following:
...
printers -- Настройки системы печа�[0m
privacy -- Модуль kcontrol, очищающ�[0m
profilechooser -- Mandriva KDE profilechooser
proxy -- Настройка серверов прок�[0m
...
(I can add screenshot)
Is it supposed to work at all? Using current CVS.
[-- Attachment #1.2: _kcmshell --]
[-- Type: text/plain, Size: 2278 bytes --]
#compdef kcmshell
# kcmshell is a command line interface to KDE configuration modules
_kcmshell_list_modules() {
local -a x
x=( ${${(f)"$(kcmshell --list 2> /dev/null)"}[2,-1]/[[:space:]]##-[[:space:]]/:})
(( $#x )) || return 1
_describe -t modules "KDE configuration module" x
}
_kcmshell() {
local expl
local -a context state line
typeset -A opt_args
_arguments \
'--help[show help message]' \
'--help-qt[show Qt specific options]' \
'--help-kde[show KDE specific options]' \
'--help-all[show all options]' \
'--author[show author information]' \
'-v[show version information]' \
'--version[show version information]' \
'--license[show license information]' \
'(*)--list[show all available modules]' \
'--display=:X display:_x_display' \
'--session=:session id for restoring application: ' \
'--cmap[use private colormap (8-bit display)]' \
'--ncols=:limit on number of colors (8-bit display): ' \
'--nograb[never grab mouse or keyboard]' \
'--dograb[override nograb in debugger]' \
'--sync[switch to synchronous mode when debugging]' \
'--fn=:font name:_x_font' \
'--font=:font name:_x_font' \
'--bg=:background color:_x_color' \
'--background=:background color:_x_color' \
'--fg=:foreground color:_x_color' \
'--foreround=:foreground color:_x_color' \
'--btn=:button color:_x_color' \
'--button=:button color:_x_color' \
'--name=:application name: ' \
'--title=:application title (caption): ' \
'--visual=:specify visual:_x_visual' \
'--inputstyle:X input method:(onthespot overthespot offthespot root)' \
'--im:X Input Method server: ' \
'--noxim[disable X Input Method]' \
'--reverse[reverse widget layout]' \
'--caption=:name in titlebar: ' \
'--icon=:application icon: ' \
'--miniicon=:icon in titlebar: ' \
'--config=:configuration file:_files' \
'--dcopserver=:DCOP server: ' \
'--nocrashhandler[disable crash handler, allow core dumps]' \
'--waitforwm[wait for a WM_NET compatible window manager]' \
'--style=:GUI style for application: ' \
'--geometry=:client window geometry:_x_geometry' \
'(-)1:configuration module:_kcmshell_list_modules' \
&& return 0
}
_kcmshell "$@"
[-- Attachment #2: Type: application/pgp-signature, Size: 189 bytes --]
next reply other threads:[~2006-09-17 14:54 UTC|newest]
Thread overview: 9+ messages / expand[flat|nested] mbox.gz Atom feed top
2006-09-17 14:53 Andrey Borzenkov [this message]
2006-09-17 19:16 ` Peter Stephenson
2006-09-21 17:04 ` PATCH: " Andrey Borzenkov
2006-09-21 17:22 ` Peter Stephenson
2006-09-21 17:44 ` Andrey Borzenkov
2006-10-07 7:58 ` Andrey Borzenkov
2006-09-21 20:02 ` Peter Stephenson
2006-09-23 7:05 ` Andrey Borzenkov
2006-09-23 7:36 ` Andrey Borzenkov
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=200609171853.57050.arvidjaar@newmail.ru \
--to=arvidjaar@newmail.ru \
--cc=zsh-workers@sunsite.dk \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).