* PATCH: replace-string-again
@ 2006-10-10 11:15 Peter Stephenson
0 siblings, 0 replies; only message in thread
From: Peter Stephenson @ 2006-10-10 11:15 UTC (permalink / raw)
To: Zsh hackers list
I've separated out the back end of replace-string to make it easy to
repeat the last replacement operation.
Index: Doc/Zsh/contrib.yo
===================================================================
RCS file: /cvsroot/zsh/zsh/Doc/Zsh/contrib.yo,v
retrieving revision 1.63
diff -u -r1.63 contrib.yo
--- Doc/Zsh/contrib.yo 14 Aug 2006 16:58:47 -0000 1.63
+++ Doc/Zsh/contrib.yo 10 Oct 2006 11:13:56 -0000
@@ -1055,8 +1055,10 @@
similar functions while reading a value.
)
tindex(replace-string)
+tindex(replace-string-again)
tindex(replace-pattern)
-item(tt(replace-string), tt(replace-pattern))(
+xitem(tt(replace-string), tt(replace-pattern))
+item(tt(replace-string-again), tt(replace-pattern-again))(
The function tt(replace-string) implements two widgets.
If defined under the same name as the function, it prompts for two
strings; the first (source) string will be replaced by the second
@@ -1082,6 +1084,13 @@
numeric argument forces the previous values to be offered, a negative or
zero argument forces them not to be.
+The function tt(replace-string-again) can be used to repeat the
+previous replacement; no prompting is done. As with tt(replace-string), if
+the name of the widget contains the word `tt(pattern)', pattern matching
+is performed, else a literal string replacement. Note that the
+previous source and replacement text are the same whether pattern or string
+matching is used.
+
For example, starting from the line:
example(print This line contains fan and fond)
Index: Functions/Zle/replace-string
===================================================================
RCS file: /cvsroot/zsh/zsh/Functions/Zle/replace-string,v
retrieving revision 1.2
diff -u -r1.2 replace-string
--- Functions/Zle/replace-string 13 Jan 2005 15:31:53 -0000 1.2
+++ Functions/Zle/replace-string 10 Oct 2006 11:13:56 -0000
@@ -1,11 +1,11 @@
emulate -L zsh
setopt extendedglob
-autoload read-from-minibuffer
+autoload -U read-from-minibuffer replace-string-again
local p1="Replace: " p2=" with: "
-local REPLY MATCH MBEGIN MEND curwidget=$WIDGET previous
-local -a match mbegin mend
+# Saving curwidget is necessary to avoid the widget name being overwritten.
+local REPLY previous curwidget=$WIDGET
if (( ${+NUMERIC} )); then
(( $NUMERIC > 0 )) && previous=1
@@ -20,34 +20,4 @@
${previous:+$_replace_string_rep} || return 1
_replace_string_rep=$REPLY
-if [[ $curwidget = *pattern* ]]; then
- local rep2
- # The following horror is so that an & preceded by an even
- # number of backslashes is active, without stripping backslashes,
- # while preceded by an odd number of backslashes is inactive,
- # with one backslash being stripped. A similar logic applies
- # to \digit.
- local rep=$_replace_string_rep
- while [[ $rep = (#b)([^\\]#)(\\\\)#(\\|)(\&|\\<->|\\\{<->\})(*) ]]; do
- if [[ -n $match[3] ]]; then
- # Expression is quoted, strip quotes
- rep2="${match[1]}${match[2]}${match[4]}"
- else
- rep2+="${match[1]}${match[2]}"
- if [[ $match[4] = \& ]]; then
- rep2+='${MATCH}'
- elif [[ $match[4] = \\\{* ]]; then
- rep2+='${match['${match[4][3,-2]}']}'
- else
- rep2+='${match['${match[4][2,-1]}']}'
- fi
- fi
- rep=${match[5]}
- done
- rep2+=$rep
- LBUFFER=${LBUFFER//(#bm)$~_replace_string_src/${(e)rep2}}
- RBUFFER=${RBUFFER//(#bm)$~_replace_string_src/${(e)rep2}}
-else
- LBUFFER=${LBUFFER//$_replace_string_src/$_replace_string_rep}
- RBUFFER=${RBUFFER//$_replace_string_src/$_replace_string_rep}
-fi
+replace-string-again $curwidget
Index: Functions/Zle/replace-string-again
===================================================================
RCS file: Functions/Zle/replace-string-again
diff -N Functions/Zle/replace-string-again
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ Functions/Zle/replace-string-again 10 Oct 2006 11:13:56 -0000
@@ -0,0 +1,45 @@
+# Back end for replace-string; can be called as a widget to repeat
+# the previous replacement. _replace_string_src and _replace_string_rep
+# are global.
+
+# When called from replace-string, we need to use the widget
+# name passed to decide whether to do pattern matching: the widget
+# may since have been overwritten.
+local MATCH MBEGIN MEND curwidget=${1:-$WIDGET}
+local -a match mbegin mend
+
+if [[ -z $_replace_string_src ]]; then
+ zle -M No string to replace.
+fi
+
+if [[ $curwidget = *pattern* ]]; then
+ local rep2
+ # The following horror is so that an & preceded by an even
+ # number of backslashes is active, without stripping backslashes,
+ # while preceded by an odd number of backslashes is inactive,
+ # with one backslash being stripped. A similar logic applies
+ # to \digit.
+ local rep=$_replace_string_rep
+ while [[ $rep = (#b)([^\\]#)(\\\\)#(\\|)(\&|\\<->|\\\{<->\})(*) ]]; do
+ if [[ -n $match[3] ]]; then
+ # Expression is quoted, strip quotes
+ rep2="${match[1]}${match[2]}${match[4]}"
+ else
+ rep2+="${match[1]}${match[2]}"
+ if [[ $match[4] = \& ]]; then
+ rep2+='${MATCH}'
+ elif [[ $match[4] = \\\{* ]]; then
+ rep2+='${match['${match[4][3,-2]}']}'
+ else
+ rep2+='${match['${match[4][2,-1]}']}'
+ fi
+ fi
+ rep=${match[5]}
+ done
+ rep2+=$rep
+ LBUFFER=${LBUFFER//(#bm)$~_replace_string_src/${(e)rep2}}
+ RBUFFER=${RBUFFER//(#bm)$~_replace_string_src/${(e)rep2}}
+else
+ LBUFFER=${LBUFFER//$_replace_string_src/$_replace_string_rep}
+ RBUFFER=${RBUFFER//$_replace_string_src/$_replace_string_rep}
+fi
--
Peter Stephenson <pws@csr.com> Software Engineer
CSR PLC, Churchill House, Cambridge Business Park, Cowley Road
Cambridge, CB4 0WZ, UK Tel: +44 (0)1223 692070
To access the latest news from CSR copy this link into a web browser: http://www.csr.com/email_sig.php
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2006-10-10 11:17 UTC | newest]
Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2006-10-10 11:15 PATCH: replace-string-again Peter Stephenson
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).