* PATCH: _mkdir
@ 2006-11-01 3:01 Clint Adams
0 siblings, 0 replies; only message in thread
From: Clint Adams @ 2006-11-01 3:01 UTC (permalink / raw)
To: zsh-workers
Another from R.Ramkumar.
Index: Completion/Unix/Command/_mkdir
===================================================================
RCS file: Completion/Unix/Command/_mkdir
diff -N Completion/Unix/Command/_mkdir
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ Completion/Unix/Command/_mkdir 1 Nov 2006 03:00:02 -0000
@@ -0,0 +1,70 @@
+#compdef mkdir
+
+local curcontext="$curcontext" line state \
+ args args_zsh args_cmd variant expl ret=1
+typeset -a opt_args
+
+args=(
+ '(-m --mode=)'{-m,--mode=}'[set permission mode]:numeric mode'
+ '(-p --parents)'{-p,--parents}'[make parent directories as needed]'
+ )
+
+args_zsh=('(-)*: :->dir')
+
+args_cmd=(
+ '(-v --verbose)'{-v,--verbose}'[print message for each created directory]'
+ '(- :)--help[display help information]'
+ '(- :)--version[display version information]'
+ '*: :->dir'
+ )
+
+case "$OSTYPE" in
+ linux*)
+ args_cmd=(
+ '(-Z --context=)'{-Z,--context=}'[set SELinux context]:SELinux context'
+ $args_cmd)
+ ;;
+esac
+
+_pick_variant -r variant gnu=gnu zsh='\(eval\)' unix --help
+
+# It can still happen that there is a precommand command or builtin in the line.
+# In such cases, the variant has to be modified suitably, after further checking
+# the variant of the _command_ mkdir.
+
+# I currently don't know of any way to find out what precommands are present on
+# the line. The variant should be modified like this once a way is found out:
+
+# if [[ $variant == zsh ]]; then
+# if [[ $precommand = *command* ]]; then
+# _mkdir_command () { command mkdir "$@" }
+# _pick_variant -c _mkdir_command -r variant gnu=gnu unix --help
+# fi
+# elif [[ $precommand = *builtin* ]]; then
+# variant=zsh
+# fi
+
+if [[ $variant == zsh ]]; then
+ args+=($args_zsh)
+else
+ args+=($args_cmd)
+fi
+
+# remove long options?
+[[ $variant != gnu ]] && args=( ${${${args:#(|*\))--*}//--[^ )]#/}/\( #\)/} )
+
+_arguments -C -s $args && ret=0
+
+case "$state" in
+ dir)
+ if (( $ret )) && [[ ! -prefix - ]] || \
+ [[ $variant == zsh && ${#${${words[2,-1]}:#-*}} -gt 0 ]]; then
+ _wanted parent-directory expl \
+ 'parent directory (alternatively specify name of directory)' \
+ _path_files -/ || _message 'name of directory'
+ ret=0
+ fi
+ ;;
+esac
+
+return ret
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2006-11-01 3:02 UTC | newest]
Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2006-11-01 3:01 PATCH: _mkdir Clint Adams
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).