umount /f/b<TAB> → /foo/bar

umount /f/b<TAB> → /foo/bar

[Daniel Shahaf]

I'd like «umount /f/b<TAB>» to complete to «umount /foo/bar».  Currently
it doesn't, due to _canonical_paths_add_paths() doing its own matching
obliviously to matchspecs in effect.

I tried to patch this.  I got it partly working: with the following
patch, «umount /f/b<TAB>» would honour matchspecs but «umount ../f/b<TAB>»
would not.  See the '###' comment within for the point I'm stuck at.

Hints?

Cheers,

Daniel


[[[
diff --git a/Completion/Unix/Command/_mount b/Completion/Unix/Command/_mount
index a3b58bb..a43085a 100644
--- a/Completion/Unix/Command/_mount
+++ b/Completion/Unix/Command/_mount
@@ -965,8 +965,8 @@ udevordir)
 
   _alternative \
     'device-labels:device label:compadd -a dev_tmp' \
-    'device-paths: device path:_canonical_paths -A dpath_tmp -N device-paths device\ path' \
-    'directories:mount point:_canonical_paths -A mp_tmp -N directories mount\ point' && ret=0
+    'device-paths: device path:_canonical_paths -A dpath_tmp -N -M "r:|/=* r:|=*" device-paths device\ path' \
+    'directories:mount point:_canonical_paths -A mp_tmp -N -M "r:|/=* r:|=*" directories mount\ point' && ret=0
   ;;
 labels)
   _wanted labels expl 'disk label' compadd /dev/disk/by-label/*(:t) && ret=0
diff --git a/Completion/Unix/Type/_canonical_paths b/Completion/Unix/Type/_canonical_paths
index 2fdbaa6..542f418 100644
--- a/Completion/Unix/Type/_canonical_paths
+++ b/Completion/Unix/Type/_canonical_paths
@@ -59,6 +59,11 @@ _canonical_paths_get_canonical_path() {
 }
 
 _canonical_paths_add_paths () {
+  # origpref = original prefix
+  # expref = expanded prefix
+  # curpref = current prefix
+  # canpref = canonical prefix
+  # rltrim = suffix to trim and readd
   local origpref=$1 expref rltrim curpref canpref subdir
   [[ $2 != add ]] && matches=()
   expref=${~origpref} 2>/dev/null
@@ -73,13 +78,34 @@ _canonical_paths_add_paths () {
   [[ $curpref == */ && $canpref == *[^/] ]] && canpref+=/
   canpref+=$rltrim
   [[ $expref == *[^/] && $canpref == */ ]] && origpref+=/
-  matches+=(${${(M)files:#$canpref*}/$canpref/$origpref})
+
+  # Append to $matches the subset of $files that matches $canpref.
+  if [[ $canpref == $origpref ]]; then
+    # This codepath honours any -M matchspec parameters.
+    () {
+      local -a tmp_buffer
+      compadd -A tmp_buffer "$__gopts[@]" -a files
+      matches+=( "${(@)tmp_buffer/$canpref/$origpref}" )
+    }
+  else
+    # ### Ideally, this codepath would do what the 'if' above does,
+    # ### but telling compadd to pretend the "word on the command line"
+    # ### is ${"the word on the command line"/$origpref/$canpref}.
+    matches+=(${${(M)files:#$canpref*}/$canpref/$origpref})
+  fi
+
   for subdir in $expref?*(@); do
     _canonical_paths_add_paths ${subdir/$expref/$origpref} add
   done
 }
 
 _canonical_paths() {
+  # The following parameters are used by callee functions:
+  #    __gopts
+  #    matches
+  #    files
+  #    (possibly others)
+
   local __index
   typeset -a __gopts __opts
 
]]]

Re: umount /f/b<TAB> -> /foo/bar

[Bart Schaefer]

On Aug 19,  3:56pm, Daniel Shahaf wrote:
}
} +    # This codepath honours any -M matchspec parameters.
} +    () {
} +      local -a tmp_buffer
} +      compadd -A tmp_buffer "$__gopts[@]" -a files
} +      matches+=( "${(@)tmp_buffer/$canpref/$origpref}" )
} +    }
} +  else
} +    # ### Ideally, this codepath would do what the 'if' above does,
} +    # ### but telling compadd to pretend the "word on the command line"
} +    # ### is ${"the word on the command line"/$origpref/$canpref}.
} +    matches+=(${${(M)files:#$canpref*}/$canpref/$origpref})
} +  fi

Perhaps some variation on

    compadd -M "B:${(b)origpref}=${(b)canpref}" -a files

??  Some cases of mount point names containing unusual characters might
be a little weird.

Re: umount /f/b<TAB> -> /foo/bar

[Daniel Shahaf]

Bart Schaefer wrote on Fri, Aug 19, 2016 at 22:35:13 -0700:
> On Aug 19,  3:56pm, Daniel Shahaf wrote:
> }
> } +    # This codepath honours any -M matchspec parameters.
> } +    () {
> } +      local -a tmp_buffer
> } +      compadd -A tmp_buffer "$__gopts[@]" -a files
> } +      matches+=( "${(@)tmp_buffer/$canpref/$origpref}" )
> } +    }
> } +  else
> } +    # ### Ideally, this codepath would do what the 'if' above does,
> } +    # ### but telling compadd to pretend the "word on the command line"
> } +    # ### is ${"the word on the command line"/$origpref/$canpref}.
> } +    matches+=(${${(M)files:#$canpref*}/$canpref/$origpref})
> } +  fi
> 
> Perhaps some variation on
> 
>     compadd -M "B:${(b)origpref}=${(b)canpref}" -a files
> 
> ??  Some cases of mount point names containing unusual characters might
> be a little weird.

I couldn't get that to work.  Neither did assigning to words[CURRENT].

I'm tempted to push the patch as is, though, since it adds matchspecs
honouring to one use-case and doesn't break others.

Thanks,

Daniel