Re: PATCH: HTML Tidy completion

Re: PATCH: HTML Tidy completion

[Peter Stephenson]

Doug Kearns wrote:
> Attached is a completion function for HTML Tidy.

Is anybody keeping track of adding contributed completions now Sven is
only intermittently available?  Because I'm not and someone ought to.

-- 
Peter Stephenson <pws@csr.com>                  Software Engineer
CSR Ltd., Science Park, Milton Road,
Cambridge, CB4 0WH, UK                          Tel: +44 (0)1223 692070


**********************************************************************
The information transmitted is intended only for the person or
entity to which it is addressed and may contain confidential 
and/or privileged material. 
Any review, retransmission, dissemination or other use of, or
taking of any action in reliance upon, this information by 
persons or entities other than the intended recipient is 
prohibited.  
If you received this in error, please contact the sender and 
delete the material from any computer.
**********************************************************************

RE: PATCH: HTML Tidy completion

[Borzenkov Andrey]

> Doug Kearns wrote:
> > Attached is a completion function for HTML Tidy.
> 
> Is anybody keeping track of adding contributed completions now Sven is
> only intermittently available?  Because I'm not and someone ought to.
> 


completion functions guru is Oliver ...

PATCH: HTML Tidy completion

[Doug Kearns]

[-- Attachment #1: Type: text/plain, Size: 64 bytes --]

Attached is a completion function for HTML Tidy.

Regards,
Doug

[-- Attachment #2: _tidy --]
[-- Type: text/plain, Size: 6511 bytes --]

#compdef tidy

# HTML Tidy for Linux/x86 (release date: 1st December 2002; built on Jan 30 2003, at 20:01:07)

local access autobool boolean doctype encoding

access=( 1 2 3 )
boolean=( yes no )
autobool=( auto $boolean )
doctype=( auto omit strict loose transitional )
encoding=( ascii latin1 raw utf8 iso2022 mac utf16le utf16be utf16 win1252 big5 shiftjis )

_arguments \
  '-'{indent,i}'[indent element content]' \
  '-'{omit,o}'[omit optional end tags]' \
  '-wrap[wrap text at the specified <column> (default is 68)]:column:' \
  '-'{upper,u}'[force tags to upper case (default is lower case)]' \
  '-'{clean,c}'[replace FONT, NOBR and CENTER tags by CSS]' \
  '-'{bare,b}'[strip out smart quotes and em dashes, etc.]' \
  '-'{numeric,n}'[output numeric rather than named entities]' \
  '-'{errors,e}'[only show errors]' \
  '-'{quiet,q}'[suppress nonessential output]' \
  '-xml[specify the input is well formed XML]' \
  '(-asxml -asxhtml -ashtml)-'{asxml,asxhtml}'[convert HTML to well formed XHTML]' \
  '(-asxml -asxhtml)-ashtml[force XHTML to well formed HTML]' \
  '-slides[burst into slides on H2 elements]' \
  '-access[do additional accessibility checks (<level> = 1, 2, 3)]:level:(${access[@]})' \
  '-raw[output values above 127 without conversion to entities]' \
  '(       -latin -iso2022 -utf8 -mac -win1252 -utf16le -utf16be -utf16 -shiftjis -big5)-ascii[use US-ASCII for output, ISO-8859-1 for input]' \
  '(-ascii        -iso2022 -utf8 -mac -win1252 -utf16le -utf16be -utf16 -shiftjis -big5)-latin1[use ISO-8859-1 for both input and output]' \
  '(-ascii -latin          -utf8 -mac -win1252 -utf16le -utf16be -utf16 -shiftjis -big5)-iso2022[use ISO-2022 for both input and output]' \
  '(-ascii -latin -iso2022       -mac -win1252 -utf16le -utf16be -utf16 -shiftjis -big5)-utf8[use UTF-8 for both input and output]' \
  '(-ascii -latin -iso2022 -utf8      -win1252 -utf16le -utf16be -utf16 -shiftjis -big5)-mac[use MacRoman for input, US-ASCII for output]' \
  '(-ascii -latin -iso2022 -utf8 -mac          -utf16le -utf16be -utf16 -shiftjis -big5)-win1252[use Windows-1252 for input, US-ASCII for output]' \
  '(-ascii -latin -iso2022 -utf8 -mac -win1252          -utf16be -utf16 -shiftjis -big5)-utf16le[use UTF-16LE for both input and output]' \
  '(-ascii -latin -iso2022 -utf8 -mac -win1252 -utf16le          -utf16 -shiftjis -big5)-utf16be[use UTF-16BE for both input and output]' \
  '(-ascii -latin -iso2022 -utf8 -mac -win1252 -utf16le -utf16be        -shiftjis -big5)-utf16[use UTF-16 for both input and output]' \
  '(-ascii -latin -iso2022 -utf8 -mac -win1252 -utf16le -utf16be -utf16           -big5)-shiftjis[use Shift_JIS for both input and output]' \
  '(-ascii -latin -iso2022 -utf8 -mac -win1252 -utf16le -utf16be -utf16 -shiftjis      )-big5[use Big5 for both input and output]' \
  '-config[set configuration options from the specified <file>]:configuration file:_files' \
  '-f[write errors to the specified <file>]:error file:_files' \
  '-'{modify,m}'[modify the original input files]' \
  '(- *)-'{version,v}'[show the version of Tidy]' \
  '(- *)-'{help,h,\?}'[list the command line options]' \
  '(- *)-help-config[list all configuration options]' \
  '(- *)-show-config[list the current configuration settings]' \
  '--indent-spaces:integer:' \
  '--wrap:integer:' \
  '--wrap-attributes:boolean:(${boolean[@]})' \
  '--wrap-script-literals:boolean:(${boolean[@]})' \
  '--wrap-sections:boolean:(${boolean[@]})' \
  '--wrap-asp:boolean:(${boolean[@]})' \
  '--wrap-jste:boolean:(${boolean[@]})' \
  '--wrap-php:boolean:(${boolean[@]})' \
  '--literal-attributes:boolean:(${boolean[@]})' \
  '--tab-size:integer:' \
  '--markup:boolean:(${boolean[@]})' \
  '--quiet:boolean:(${boolean[@]})' \
  '--tidy-mark:boolean:(${boolean[@]})' \
  '--indent:boolean:(${autobool[@]})' \
  '--indent-attributes:boolean:(${boolean[@]})' \
  '--hide-endtags:boolean:(${boolean[@]})' \
  '--input-xml:boolean:(${boolean[@]})' \
  '--output-xml:boolean:(${boolean[@]})' \
  '--output-xhtml:boolean:(${boolean[@]})' \
  '--output-html:boolean:(${boolean[@]})' \
  '--add-xml-pi:boolean:(${boolean[@]})' \
  '--add-xml-decl:boolean:(${boolean[@]})' \
  '--assume-xml-procins:boolean:(${boolean[@]})' \
  '--raw:boolean:(${boolean[@]})' \
  '--uppercase-tags:boolean:(${boolean[@]})' \
  '--uppercase-attributes:boolean:(${boolean[@]})' \
  '--bare:boolean:(${boolean[@]})' \
  '--clean:boolean:(${boolean[@]})' \
  '--logical-emphasis:boolean:(${boolean[@]})' \
  '--word-2000:boolean:(${boolean[@]})' \
  '--drop-empty-paras:boolean:(${boolean[@]})' \
  '--drop-font-tags:boolean:(${boolean[@]})' \
  '--drop-proprietary-attribute:boolean:(${boolean[@]})' \
  '--enclose-text:boolean:(${boolean[@]})' \
  '--enclose-block-text:boolean:(${boolean[@]})' \
  '--alt-text:string:' \
  '--add-xml-space:boolean:(${boolean[@]})' \
  '--fix-bad-comments:boolean:(${boolean[@]})' \
  '--split:boolean:(${boolean[@]})' \
  '--break-before-br:boolean:(${boolean[@]})' \
  '--numeric-entities:boolean:(${boolean[@]})' \
  '--quote-marks:boolean:(${boolean[@]})' \
  '--quote-nbsp:boolean:(${boolean[@]})' \
  '--quote-ampersand:boolean:(${boolean[@]})' \
  '--write-back:boolean:(${boolean[@]})' \
  '--keep-time:boolean:(${boolean[@]})' \
  '--show-warnings:boolean:(${boolean[@]})' \
  '--error-file:error file:_files' \
  '--show-body-only:boolean:(${boolean[@]})' \
  '--slide-style:file:_files' \
  '--new-inline-tags:tag names:' \
  '--new-blocklevel-tags:tag names:' \
  '--new-empty-tags:tag names:' \
  '--new-pre-tags:tag names:' \
  '--char-encoding:encoding:(${encoding[@]})' \
  '--input-encoding:encoding:(${encoding[@]})' \
  '--output-encoding:encoding:(${encoding[@]})' \
  '--doctype:doctype:(${doctype[@]})' \
  '--fix-backslash:boolean:(${boolean[@]})' \
  '--gnu-emacs:boolean:(${boolean[@]})' \
  '--fix-uri:boolean:(${boolean[@]})' \
  '--lower-literals:boolean:(${boolean[@]})' \
  '--hide-comments:boolean:(${boolean[@]})' \
  '--indent-cdata:boolean:(${boolean[@]})' \
  '--force-output:boolean:(${boolean[@]})' \
  '--show-errors:integer:' \
  '--ascii-chars:boolean:(${boolean[@]})' \
  '--join-classes:boolean:(${boolean[@]})' \
  '--join-styles:boolean:(${boolean[@]})' \
  '--escape-cdata:boolean:(${boolean[@]})' \
  '--repeated-attributes:value:(keep-first keep-last)' \
  '--output-bom:boolean:(${autobool[@]})' \
  '--replace-color:boolean:(${boolean[@]})' \
  '--css-prefix:string:' \
  '--accessibility-check:integer:(${access[@]})' \
  '*:file:_files'

Re: PATCH: HTML Tidy completion

[Peter Stephenson]

Borzenkov Andrey wrote:
> 
> > Doug Kearns wrote:
> > > Attached is a completion function for HTML Tidy.
> > 
> > Is anybody keeping track of adding contributed completions now Sven is
> > only intermittently available?  Because I'm not and someone ought to.
> > 
>
> completion functions guru is Oliver ...

Now I look it at the ChangeLog, I can see Oliver's been busy adding the
vaious stuff posted by users.

-- 
Peter Stephenson <pws@csr.com>                  Software Engineer
CSR Ltd., Science Park, Milton Road,
Cambridge, CB4 0WH, UK                          Tel: +44 (0)1223 692070


**********************************************************************
The information transmitted is intended only for the person or
entity to which it is addressed and may contain confidential 
and/or privileged material. 
Any review, retransmission, dissemination or other use of, or
taking of any action in reliance upon, this information by 
persons or entities other than the intended recipient is 
prohibited.  
If you received this in error, please contact the sender and 
delete the material from any computer.
**********************************************************************

Re: PATCH: HTML Tidy completion

[Oliver Kiddle]

On 30 Jan, you wrote:
> Doug Kearns wrote:
> > Attached is a completion function for HTML Tidy.
> 
> Is anybody keeping track of adding contributed completions now Sven is
> only intermittently available?  Because I'm not and someone ought to.

I've kept track of them. I think the only things missing are ones which
were only half finished - gpg, mplayer and the OpenBSD _bsd_pkg changes
earlier this month come to mind. There was also an ecasound completion
some while back which I think was finished but was never added. I'll
perhaps dig these out and add them. I'm not going to be available next
week though as I'm off skiing.

Anyway, I'll add the HTML Tidy completion. Thanks Doug.

Oliver

This e-mail and any attachment is for authorised use by the intended recipient(s) only.  It may contain proprietary material, confidential information and/or be subject to legal privilege.  It should not be copied, disclosed to, retained or used by, any other party.  If you are not an intended recipient then please promptly delete this e-mail and any attachment and all copies and inform the sender.  Thank you.