* [PATCH] Completion: Add _nginx
@ 2018-07-20 2:46 dana
0 siblings, 0 replies; only message in thread
From: dana @ 2018-07-20 2:46 UTC (permalink / raw)
To: Zsh hackers list
Simple one: completion for nginx
dana
diff --git a/Completion/Unix/Command/_nginx b/Completion/Unix/Command/_nginx
new file mode 100644
index 000000000..7d785c822
--- /dev/null
+++ b/Completion/Unix/Command/_nginx
@@ -0,0 +1,20 @@
+#compdef nginx
+
+local -ah signals=(
+ 'quit\:shut down gracefully (SIGQUIT)'
+ 'reload\:reload configuration (SIGHUP)'
+ 'reopen\:re-open log files (SIGUSR1)'
+ 'stop\:shut down quickly (SIGTERM)'
+)
+
+_arguments -s -S : \
+ '(: * -)'{-\?,-h}'[display help information]' \
+ '(: * -)-v[display version information]' \
+ '(: * -)-V[display version information and configure options]' \
+ '-c+[specify configuration file]:configuration file:_files' \
+ '-g+[specify global configuration directives]:configuration directives' \
+ '-p+[specify prefix path]:prefix path:_directories' \
+ '(-s)-q[suppress non-error messages (with -t/-T)]' \
+ "(-q -t -T)-s+[send specified signal to master process]:signal:((${(j< >)${(@q-)signals}}))" \
+ '(-s -T)-t[test configuration]' \
+ '(-s -t)-T[test and dump configuration]'
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2018-07-20 2:47 UTC | newest]
Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2018-07-20 2:46 [PATCH] Completion: Add _nginx dana
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).