* [PATCH] new completion function for od
@ 2014-01-22 15:59 Jun T.
2014-01-30 14:53 ` Jun T.
0 siblings, 1 reply; 3+ messages in thread
From: Jun T. @ 2014-01-22 15:59 UTC (permalink / raw)
To: zsh-workers
---
This is a new completion function for the od (octal dump) command
Completion/Unix/Command/_od | 71 +++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 71 insertions(+)
create mode 100644 Completion/Unix/Command/_od
diff --git a/Completion/Unix/Command/_od b/Completion/Unix/Command/_od
new file mode 100644
index 0000000..d542597
--- /dev/null
+++ b/Completion/Unix/Command/_od
@@ -0,0 +1,71 @@
+#compdef od
+
+local context state state_descr line args ret=1
+local -A opt_args
+
+args=(
+ '(-A --address-radix)'{-A+,--address-radix=}'[file offset base]:base:((d\:decimal o\:octal x\:hexadecimal n\:none))'
+ '(-j --skip-bytes)'{-j+,--skip-bytes=}'[skip specified bytes]:bytes'
+ '(-N --read-bytes)'{-N+,--read-bytes=}'[dump at most specified bytes]:bytes'
+ '*'{-t+,--format=}'[specify output format]:format string:->format'
+ '(-v --output-duplicates)'{-v,--output-duplicates}'[do not use * to mark line suppression]'
+ '-a[output named characters (-t a)]'
+ '-b[output octal bytes (-t o1)]'
+ '-c[output characters with C-style escape (-t c)]'
+ '-d[output unsigned decimal shorts (-t u2)]'
+ '-f[output single-precision floats (-t fF)]'
+ {-h,-x}'[output hexadecimal shorts (-t x2)]'
+ '-i[output decimal integers (-t dI)]'
+ {-l,-I,-L}'[output decimal longs (-t dL)]'
+ {-o,-B}'[output octal shorts (-t o2)]'
+ '-s[output decimal shorts (-t d2)]'
+ '*:files:_files'
+)
+
+if _pick_variant gnu=GNU unix --version; then
+ # -h -B -I and -L are obsolescent and undocumented
+ args=( ${(R)args:#(|\*)(|\(*\))-[hBIL]*} )
+ args+=(
+ {-S+,--strings=-}'[output strings of at least specfied bytes long]:length'
+ {-w-,--width=-}'[output specified bytes per line]:bytes'
+ '(- : *)--help[display help and exit]'
+ '(- : *)--version[output version information and exit]'
+ )
+else
+ args=( ${(R)args:#(|\*)(|\(*\))--*} ) # remove long options
+ case "$OSTYPE" in
+ (darwin*|freebsd*|dragonfly*|openbsd*)
+ args+=(
+ '-D[output unsigned decimal ints (-t u4)]'
+ {-e,-F}'[output double-precision floats (-t fD)]'
+ {-H,-X}'[output hexadecimal ints (-t x4)]'
+ '-O[output octal ints (-t o4)]'
+ )
+ ;;
+ (*)
+ # POSIX options only
+ args=( ${(M)args:#(|\*)(|\(*\))-[AjNtvbcdosx]*} )
+ ;;
+ esac
+fi
+
+_arguments -s -S : "$args[@]" && return 0
+
+case "$state" in
+ (format)
+ compset -P '*[acCSIL1248FDL]'
+ if compset -P '*[doux]'; then
+ args=( 'C:char' 'S:short' 'I:int' 'L:long' 1 2 4 8 )
+ _describe -t integer-size 'size of integer' args && ret=0
+ elif compset -P '*f'; then
+ args=( 'F:float' 'D:double' 'L:long double' )
+ _describe -t float-size 'size of float' args && ret=0
+ fi
+ args=( 'a:named character' 'c:character (C-style escape)'
+ 'd:decimal' 'o:octal' 'u:unsigned decimal'
+ 'x:hexadecimal' 'f:floating-point number' )
+ _describe -t type-specifier 'type specifier' args && ret=0
+ ;;
+esac
+
+return ret
--
1.8.3.4 (Apple Git-47)
^ permalink raw reply [flat|nested] 3+ messages in thread
* Re: [PATCH] new completion function for od
2014-01-22 15:59 [PATCH] new completion function for od Jun T.
@ 2014-01-30 14:53 ` Jun T.
2014-01-30 15:54 ` Peter Stephenson
0 siblings, 1 reply; 3+ messages in thread
From: Jun T. @ 2014-01-30 14:53 UTC (permalink / raw)
To: zsh-workers
Could someone check this and push to the repo if it is OK?
TIA
Jun
^ permalink raw reply [flat|nested] 3+ messages in thread
* Re: [PATCH] new completion function for od
2014-01-30 14:53 ` Jun T.
@ 2014-01-30 15:54 ` Peter Stephenson
0 siblings, 0 replies; 3+ messages in thread
From: Peter Stephenson @ 2014-01-30 15:54 UTC (permalink / raw)
To: zsh-workers
On Thu, 30 Jan 2014 23:53:58 +0900
"Jun T." <takimoto-j@kba.biglobe.ne.jp> wrote:
> Could someone check this and push to the repo if it is OK?
Done (so nobody else tries)
pws
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2014-01-30 15:54 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2014-01-22 15:59 [PATCH] new completion function for od Jun T.
2014-01-30 14:53 ` Jun T.
2014-01-30 15:54 ` Peter Stephenson
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).