* Completion/Unix/_emacsclient
@ 2012-04-23 6:47 Nikolai Weibull
0 siblings, 0 replies; only message in thread
From: Nikolai Weibull @ 2012-04-23 6:47 UTC (permalink / raw)
To: Zsh Workers
[-- Attachment #1: Type: text/plain, Size: 56 bytes --]
Hi!
Please find Completion/Unix/_emacsclient attached.
[-- Attachment #2: _emacsclient --]
[-- Type: application/octet-stream, Size: 1193 bytes --]
#compdef emacsclient
local state line curcontext="$curcontext" ret=1
typeset -A opt_args
_arguments -C -S \
'(-a --alternate-editor)'{-a,--alternate-editor=}'[use given editor if no server available]' \
'(-c --create-frame)'{-c,--create-frame}'[create and use new frame]' \
'(-d --display)'{-d,--display=}'[tell server to display file on given display]: :_x_display' \
'--eval[evaluate arguments as lisp expressions]' \
'(-f --server-file)'{-f,--server-file=}'[use given TCP configuration file for communication]:TCP configuration file:_files' \
'(-n --no-wait)'{-n,--no-wait}'[return immediately instead of waiting for editing to finish]' \
'(-nw -t --terminal)'{-nw,-t,--terminal}'[open new frame on current terminal]' \
'(-s --socket-name)'{-s,--socket-name=}'[use given socket file for communication]:socket:_files -g "*(=)"' \
'(- *)'{-V,--version}'[display version information and exit]' \
'(- *)'{-H,--help}'[display help information and exit]' \
'*: :->file-or-expression' && ret=0
case $state in
(file-or-expression)
if [[ -n ${opt_args[(I)--eval]} ]]; then
_message 'lisp expression'
else
_files && ret=0
fi
;;
esac
return ret
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-04-23 6:47 UTC | newest]
Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2012-04-23 6:47 Completion/Unix/_emacsclient Nikolai Weibull
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).