Re: [PATCH] Improve extra-verbose completion of array params

[Marlon Richert <marlon.richert@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 777 bytes --]

On Mon, May 17, 2021 at 1:09 AM Oliver Kiddle <opk@zsh.org> wrote:
>
> On 27 Apr, Marlon Richert wrote:
> > This patch improves the extra-verbose completion display strings for
> > arrays and associative arrays.
> > -    verbose=(
> > -        ${described[@]:/(#m)*/"${MATCH}:${(@q+)${(Pkv@q+)MATCH}//\\/\\\\}"} )
> > +    verbose=( ${${${(f@)"$( typeset -m $described )"}/=/:}[@]//'\'/'\\'} )
>
> Why the use of -m here? Is that to avoid it creating variables (which
> may not matter especially in the subshell). Do we need to be concerned
> about the possibility of glob characters appearing there and producing
> more output than expected?

Here's a new version of the patch, which hopefully addresses the
concerns above and has a satisfactorily descriptive commit message.

[-- Attachment #2: 0001-Improve-extra-verbose-completion-display-strings-for.txt --]
[-- Type: text/plain, Size: 3559 bytes --]

From e70cf2b4f48fce90f83a89d24e369b9f5eb10fd7 Mon Sep 17 00:00:00 2001
From: Marlon Richert <marlon.richert@gmail.com>
Date: Mon, 17 May 2021 14:49:02 +0300
Subject: [PATCH] Improve extra-verbose completion display strings for array
 parameter values

---
 Completion/Zsh/Type/_parameters | 16 ++++++++++------
 Test/Y01completion.ztst         | 14 +++++++++-----
 2 files changed, 19 insertions(+), 11 deletions(-)

diff --git a/Completion/Zsh/Type/_parameters b/Completion/Zsh/Type/_parameters
index 00c181e11..549b2157b 100644
--- a/Completion/Zsh/Type/_parameters
+++ b/Completion/Zsh/Type/_parameters
@@ -11,9 +11,9 @@ if compset -P '*:'; then
   return
 fi
 
-local MATCH i pfilt
-local -i MBEGIN MEND nm=$compstate[nmatches]
-local -a expl pattern=(-g \*) normal described verbose faked fakes tmp
+local i pfilt
+local -i nm=$compstate[nmatches]
+local -a expl pattern=( -g \* ) normal described verbose faked fakes tmp
 
 zstyle -t ":completion:${curcontext}:parameters" prefix-needed &&
     [[ $PREFIX != [_.]* ]] &&
@@ -27,8 +27,13 @@ if zstyle -t ":completion:${curcontext}:parameters" extra-verbose; then
   )
   compadd "$@" "$expl[@]" -D described -a - described
   if (( $#described )); then
-    verbose=(
-        ${described[@]:/(#m)*/"${MATCH}:${(@q+)${(Pkv@q+)MATCH}//\\/\\\\}"} )
+    # Normally, calling typeset without flags would print the values of its
+    # arguments. However, inside a function, it instead declare its arguments
+    # as local variables and outputs nothing. Thus, to force it print out
+    # parameter values, we pass it the -m flag.
+    verbose=( 
+        ${${${(f@)"$( typeset -m ${(@b)described} )"}/=/:}[@]//'\'/'\\'} 
+    )
     _describe -t parameters parameter verbose "$@" "$expl[@]"
   fi
 
@@ -52,4 +57,3 @@ compadd "$@" "$expl[@]" - "$normal[@]" "${(@)fakes:|described}" \
     "${(@)${(@)${(@M)faked:#${~pattern[2]}}%%:*}:|described}"
 
 (( compstate[nmatches] > nm ))
-return 0
diff --git a/Test/Y01completion.ztst b/Test/Y01completion.ztst
index 2c6d25d9a..882a0adc4 100644
--- a/Test/Y01completion.ztst
+++ b/Test/Y01completion.ztst
@@ -255,15 +255,18 @@ F:regression test workers/31611
 >FI:{file1}
 >FI:{file2}
 
-  comptesteval "bar=({$'\\0'..$'\\C-?'}); baz=\$bar"
+  comptesteval "typeset -a bar=({$'\\0'..$'\\C-?'})"
+  comptesteval 'typeset -A bat=( "$bar[@]" )'
+  comptesteval 'typeset bay="$bar"'
   comptesteval 'zstyle ":completion:*:parameters" extra-verbose yes'
-  comptesteval 'zstyle ":completion:*" fake-parameters bar baz:array'
+  comptesteval 'zstyle ":completion:*" fake-parameters bar bat bay'
   comptest $': $ba\t'
 0:extra-verbose shows parameter values
 >line: {: $ba}{}
 >DESCRIPTION:{parameter}
->NO:{bar  -- '^@' '^A' '^B' '^C' '^D' '^E' '^F' '^G' '^H' '\t' '\n' '^K' '^L' '^M}
->NO:{baz  -- '^@ ^A ^B ^C ^D ^E ^F ^G ^H \t \n ^K ^L ^M ^N ^O ^P ^Q ^R ^S ^T ^U ^}
+>NO:{bar  -- ( '^@' '^A' '^B' '^C' '^D' '^E' '^F' '^G' '^H' '\t' '\n' '^K' '^L' '}
+>NO:{bat  -- ( [' ']='!' ['"']='#' ['$']=% ['&']=\' ['(']=')' ['*']=+ [,]=- [.]=/}
+>NO:{bay  -- '^@ ^A ^B ^C ^D ^E ^F ^G ^H \t \n ^K ^L ^M ^N ^O ^P ^Q ^R ^S ^T ^U ^}
 
   comptesteval "path=( $ZTST_srcdir:A )"
   comptesteval 'typeset -H paths=HIDDEN'
@@ -280,7 +283,8 @@ F:regression test workers/31611
 >line: {: $ba}{}
 >DESCRIPTION:{parameter}
 >NO:{bar}
->NO:{baz}
+>NO:{bat}
+>NO:{bay}
 
   comptesteval '_tst() { local disp=( {a..z} ); compadd -ld disp $disp[@]; comppostfuncs=( _pst ) }'
   comptesteval '_pst() { local disp=( "<INSERT>$compstate[insert]</INSERT>" ); compadd -Qld disp $disp }'
-- 
2.31.1