Re: PATCH: 3.0.8: git completion update for cherry-pick

[Daniel Shahaf <d.s@daniel.shahaf.name>]

As mentioned on IRC — I'd like to review this but I don't have time to
do so right now.  @zsh-workers, feel free to beat me to it.

Mateusz Karbowy wrote on Fri, Aug 21, 2015 at 20:55:07 +0100:
> Hey Daniel
> 
> I think this covers it. I know you mentioned I shouldn't need to use
> the ${(P)} in __git_commit_ranges, but there were these two calls to
> __git_commits with either '$*' or '$* $suf', and they operated on
> compadd params before the change, so I thought it's safer this way.
> What do you think?

> diff --git a/Completion/Unix/Command/_git b/Completion/Unix/Command/_git
> index b8edc10..5f4fead 100644
> --- a/Completion/Unix/Command/_git
> +++ b/Completion/Unix/Command/_git
> @@ -495,6 +495,8 @@ _git-checkout () {
>  
>  (( $+functions[_git-cherry-pick] )) ||
>  _git-cherry-pick () {
> +  local -a git_commit_opts
> +  git_commit_opts=(--all --not HEAD --not)
>    _arguments \
>      '(- :)--quit[end revert or cherry-pick sequence]' \
>      '(- :)--continue[resume revert or cherry-pick sequence]' \
> @@ -511,7 +513,7 @@ _git-cherry-pick () {
>      '*'{-s,--strategy=}'[use given merge strategy]:merge strategy:__git_merge_strategies' \
>      '*'{-X,--strategy-option=}'[pass merge-strategy-specific option to merge strategy]' \
>      '(-e --edit -x -n --no-commit -s --signoff)--ff[fast forward, if possible]' \
> -    ': :__git_commit_ranges'
> +    ': : __git_commit_ranges -O expl -C git_commit_opts'
>  }
>  
>  (( $+functions[_git-citool] )) ||
> @@ -5602,20 +5604,29 @@ __git_remote_branch_names_noprefix () {
>  
>  (( $+functions[__git_commit_objects_prefer_recent] )) ||
>  __git_commit_objects_prefer_recent () {
> -  __git_recent_commits || __git_commit_objects
> +  local -A commit_opts_array_name
> +  zparseopts -D -E C:=commit_opts_array_name
> +
> +  __git_recent_commits -C $commit_opts_array_name || __git_commit_objects
>  }
>  
>  (( $+functions[__git_commits] )) ||
>  __git_commits () {
> +  # Separate compadd options with git commit options.
> +  local -A compadd_opts_array_name commit_opts_array_name
> +  zparseopts -D -E O:=compadd_opts_array_name C:=commit_opts_array_name
> +  (( $#compadd_opts_array_name )) && set -- "${(@P)compadd_opts_array_name}"
> +
>    # TODO: deal with things that __git_heads and __git_tags has in common (i.e.,
>    # if both exists, they need to be completed to heads/x and tags/x.
> -  local -a sopts ropt
> +  local -a sopts ropt expl
>    zparseopts -E -a sopts S: r:=ropt R: q
>    sopts+=( $ropt:q )
> +  expl=( $@ )
>    _alternative \
>      "heads::__git_heads $sopts" \
>      "commit-tags::__git_commit_tags $sopts" \
> -    'commit-objects::__git_commit_objects_prefer_recent'
> +    'commit-objects:: __git_commit_objects_prefer_recent -O expl -C $commit_opts_array_name'
>  }
>  
>  (( $+functions[__git_heads] )) ||
> @@ -5670,13 +5681,17 @@ __git_commit_objects () {
>  (( $+functions[__git_recent_commits] )) ||
>  __git_recent_commits () {
>    local gitdir expl start
> -  declare -a descr tags heads commits
> +  local -A commit_opts_array_name
> +  declare -a descr tags heads commits commit_opts
>    local i j k ret
>    integer distance_from_head
>  
> +  zparseopts -D -E C:=commit_opts_array_name
> +  (( $#commit_opts_array_name )) && commit_opts=( "${(@P)commit_opts_array_name}" )
> +
>    # Careful: most %d will expand to the empty string.  Quote properly!
>    # NOTE: we could use %D directly, but it's not available in git 1.9.1 at least.
> -  commits=("${(f)"$(_call_program commits git --no-pager log -20 --format='%h%n%d%n%s\ \(%cr\)')"}")
> +  commits=("${(f)"$(_call_program commits git --no-pager log $commit_opts -20 --format='%h%n%d%n%s\ \(%cr\)')"}")
>    __git_command_successful $pipestatus || return 1
>  
>    for i j k in "$commits[@]" ; do
> @@ -5759,13 +5774,19 @@ __git_commits2 () {
>  
>  (( $+functions[__git_commit_ranges] )) ||
>  __git_commit_ranges () {
> -  local -a suf
> +  local -A compadd_opts_array_name commit_opts_array_name
> +  zparseopts -D -E O:=compadd_opts_array_name C:=commit_opts_array_name
> +  (( $#compadd_opts_array_name )) && set -- "${(@P)compadd_opts_array_name}"
> +
> +  local -a expl suf
>    if compset -P '*..(.|)'; then
> -    __git_commits $*
> +    expl=( $* )
>    else
>      compset -S '..*' || suf=( -S .. -r '.@~ ^:\t\n\-' )
> -    __git_commits $* $suf
> +    expl=( $* $suf )
>    fi
> +
> +  __git_commits -O expl -C $commit_opts_array_name
>  }
>  
>  (( $+functions[__git_commit_ranges2] )) ||